Início / computer / Perguntas / 1828387
Accepted
BradR
Asked: 2024-02-01 23:56:46 +0800 CST

Maneira eficaz de contar os dias dentro do intervalo em um mês

  • 772

Bom dia,

Estou trabalhando em uma programação para determinar o número de dias em que uma fatura é aplicada em um mês. Algumas faturas cobrem um mês, outras 2 e outras múltiplas. Eu criei uma fórmula feia que está funcionando, mas me pergunto se há algo muito mais simples que fará o trabalho.

Na célula Q4

=SE($N4<Q$2,0,(SE(ANO($N4)=2022,0, SE(MÊS($L4)=Q$1,Q$3-$L4)) +SE(E(Q$2> $L4,$N4>Q$3),Q$3-Q$2+1,(SE(E(Q$2>$L4,Q$3>$N4,Q$2<$N4),$N4-Q$2+1, 0)))))

insira a descrição da imagem aqui

Alguma sugestão sobre algo menos complexo? Estou trabalhando com Office 365

Obrigado,

microsoft-excel

1 respostas

  1. Best Answer

    Tente algo como usar SUMPRODUCT()a função:

    insira a descrição da imagem aqui

    =SUMPRODUCT(N(TEXT(ROW(INDEX($A:$A,$L4+1):INDEX($A:$A,$N4)),"mmmm-yyyy")=TEXT(Q$2,"mmmm-yyyy")))

    Ou, se quiser incluir o último dia do mês a partir da terceira linha, use o seguinte:

    insira a descrição da imagem aqui

    =IFERROR(
    ROWS(
        INDEX($A:$A, $L4 + 1):
            INDEX($A:$A, $N4)
            INDEX($A:$A, Q$2):
                INDEX(
                    $A:$A,
                    Q$3
                )
    ),
    0
)

    Ou simplesmente use isso usando MAX()&MIN()

    insira a descrição da imagem aqui

    =MAX(0,MIN($N4,Q$3)+1-MAX($L4+1,Q$2))

    A fórmula acima precisa ser preenchida e preenchida corretamente!

    E usar MAKEARRAY()um pode espalhar toda a saída de uma só vez:

    insira a descrição da imagem aqui

    =LET(
     _Start, L4:L6,
     _End, N4:N6,
     _StartM, Q2:AB2,
     _EndM, Q3:AB3,
     _Rows, ROWS(_Start),
     _Columns, COLUMNS(_StartM),
     MAKEARRAY(_Rows,_Columns,LAMBDA(r,c,
     MAX(0,MIN(INDEX(_End,r),INDEX(_EndM,c))+1-MAX(INDEX(_Start,r)+1,INDEX(_StartM,c))))))
    • 1

relate perguntas