Crie uma tabela contábil de dupla entrada separando as transações

O Power Query fará isso com bastante facilidade. Coloque seus dados em uma tabela para usar como fonte ou talvez use uma fonte de dados externa, como CSV ou SQL.

No entanto, você obtém os dados em PQ em um formato semelhante ao seu post, então você quer certificar-se de que a etapa Changed Type está definindo tipos de dados adequados para cada coluna. Remova a coluna "Tipo" que você não precisa.

Achei útil renomear "Valor" para "Valor original" neste ponto, para que eu possa reutilizar o nome da coluna posteriormente. Selecione Valor e data originais e vá para Transformar > Colunas não dinâmicas > Outras colunas.

Este é o passo crucial para obter duas linhas onde havia apenas uma. Depois disso, você precisa adicionar várias colunas condicionais para obter os valores "Para a conta" em uma coluna chamada "Para a conta" e nulos para as outras e vice-versa para "Da conta".

A nova coluna "Valor" é um pouco mais complicada. Você pode executar várias etapas e excluir as colunas intermediárias ou escrever uma fórmula personalizada do zero ou em algum lugar intermediário - adicione uma coluna condicional que procure por To / From e, em AMBOS os casos, retorne a coluna Valor. Em seguida, na barra de fórmulas, basta editar a metade disso inserindo "-1 *" na frente de [Valor original].

Da mesma forma, adicione uma coluna condicional para Tipo (Receita ou Despesa)

Altere a coluna Valor para o tipo de dados Moeda (ou decimal, se preferir, mas decimais fixos geralmente são úteis). Remova as colunas indesejadas para manter apenas as colunas necessárias (portanto, livre-se de Valor, Atributo e Valor Original).

Feche e carregue - bom para ir! Seu código M (no Editor Avançado) ficará mais ou menos assim:

let
        Source = Excel.CurrentWorkbook(){[Name="StartingTable"]}[Content],
        #"Changed Type" = Table.TransformColumnTypes(Source,{{"Date", type date}, {"To Account", type text}, {"From Account", type text}, {"Amount", Int64.Type}, {"Type", type text}}),
        #"Removed Columns" = Table.RemoveColumns(#"Changed Type",{"Type"}),
        #"Renamed Columns" = Table.RenameColumns(#"Removed Columns",{{"Amount", "Original Amount"}}),
        #"Unpivoted Other Columns" = Table.UnpivotOtherColumns(#"Renamed Columns", {"Original Amount", "Date"}, "Attribute", "Value"),
        #"Added To Account" = Table.AddColumn(#"Unpivoted Other Columns", "To Account", each if [Attribute] = "To Account" then [Value] else null),
        #"Added From Account" = Table.AddColumn(#"Added To Account", "From Account", each if [Attribute] = "From Account" then [Value] else null),
        #"Added Amount" = Table.AddColumn(#"Added From Account", "Amount", each if [Attribute] = "To Account" then [Original Amount] else -1 * [Original Amount]),
        #"Changed Type1" = Table.TransformColumnTypes(#"Added Amount",{{"Amount", Currency.Type}}),
        #"Added Conditional Column" = Table.AddColumn(#"Changed Type1", "Type", each if [Attribute] = "To Account" then "Expense" else "Revenue"),
        #"Removed Other Columns" = Table.SelectColumns(#"Added Conditional Column",{"Date", "To Account", "From Account", "Amount", "Type"})
    in
        #"Removed Other Columns" 

Aqui está outro método usando o Power Query:

• Adicionar uma coluna de índice à tabela original
• Crie duas tabelas a partir da tabela original
  • "Créditos"
    • Transforme a entrada "Da conta" em nula
    • Torne negativo o "Valor"
    • Faça o "Tipo": Despesa
  • "Débitos"
    • Transforme a entrada "Para a conta" em nula
    • Faça o "Tipo": Receita
• Então
  • Recombinar as duas tabelas
  • Classificar pela coluna Índice
  • Excluir a coluna Índice

Também seria possível incluir a tomada de decisão com base no número da conta para decidir sobre o Tipo e se o Valor deve ser negativo ou não.

let

//Change next line to reflect actual data source
    Source = Excel.CurrentWorkbook(){[Name="Transactions"]}[Content],
    #"Changed Type" = Table.TransformColumnTypes(Source,{
        {"Date", type date}, {"To Account", Int64.Type}, {"From Account", Int64.Type}, 
        {"Amount", Currency.Type}, {"Type", type text}}),

    #"Add Index Column" = Table.AddIndexColumn(#"Changed Type","Index"),

    Credits = Table.TransformColumns(#"Add Index Column",{
        {"From Account", each null, Int64.Type},
        {"Amount", each -_, Currency.Type},
        {"Type", each "Expense", type text}}),

    Debits = Table.TransformColumns(#"Add Index Column",{
        {"To Account", each null, Int64.Type},
        {"Type", each "Revenue", type text}}),

    Results = Table.Combine({Credits,Debits}),
    #"Sorted Rows" = Table.Sort(Results,{{"Index", Order.Ascending}}),
    #"Remove Index Column" = Table.RemoveColumns(#"Sorted Rows",{"Index"})
 
in
    #"Remove Index Column"