Converter uma tabela do Excel em linhas * colunas personalizadas

A abordagem a seguir usa a Letfunção muito flexível, que, no entanto, está disponível apenas no Excel 365 e Excel 2021:

=LET(Matrix,$A$1:$D$3,rowsMatrix,ROWS(Matrix),colsMatrix,COLUMNS(Matrix),
cellValues,SEQUENCE((rowsMatrix*colsMatrix)/2,2,0),
INDEX(Matrix,INT(cellValues/colsMatrix)+1,MOD(cellValues,colsMatrix)+1))

EDIT : Pergunta adicional nos comentários

Na abordagem descrita acima, a matriz é distribuída linha a linha entre as colunas, ou seja, a primeira linha começa com 1, 2 e assim por diante.

Para distribuir a matriz por colunas, ou seja, a coluna 1 possui valores de 1 a 6 e a coluna 2 possui valores de 7 a 12, a SEQUENCEinstrução deve ser ajustada de acordo. Em particular, a SEQUENCEinstrução controla o mecanismo de distribuição e você deseja obter um SEQUENCEque se mova verticalmente em vez de horizontalmente. Portanto, basta substituir a SEQUENCEinstrução na LETfunção pelo seguinte:

TRANSPOSE(SEQUENCE(2,(rowsMatrix*colsMatrix)/2,0))

Se você quiser entender em que medida os dois SEQUENCESdiferem, basta inserir as seguintes fórmulas no Excel:

=SEQUENCE((3*4)/2,2,0)
=TRANSPOSE(SEQUENCE(2,(3*4)/2,0))

Outra abordagem tangível seria transformar os dados em uma única coluna via (onde, por exemplo, $F$1 é a célula superior do intervalo de destino):

Opção 1:

=OFFSET($A$1,INT((ROW()-ROW($F$1))/COLUMNS($A$1:$D$1)),
MOD(ROW()-ROW($F$1),COLUMNS($A$1:$D$1)))

Opção 2:

=INDEX($A$1:$D$3,INT((ROW()-ROW($F$1))/COLUMNS($A$1:$D$1))+1,
MOD(ROW()-ROW($F$1),COLUMNS($A$1:$D$1))+1)

Assim, ambas as opções 1 e 2 são simplesmente colunas auxiliares às quais você pode aplicar a função abaixo. Como a função também funciona se você inserir a coluna inteira, essa abordagem também parece bastante flexível:

=INDEX($F:$F,SEQUENCE(6,2))