Os slides do PowerPoint (formas) não parecem herdar o texto alternativo do mestre

Na maioria dos casos, não haverá vários marcadores de posição mestre/layout de um determinado tipo (por exemplo, Título, Subtítulo, etc.) para que você possa combinar o tipo de marcador de uma forma de slide com o tipo de marcador de posição do layout do slide. Veja alguns exemplos de VBA:

Option Explicit

Sub TestThis()

    Dim osl As Slide
    Dim osh As Shape
    Dim sTemp As String
    
    For Each osl In ActivePresentation.Slides
        For Each osh In osl.Shapes
           sTemp = MasterAltText(osh)
           If Len(sTemp) > 0 Then
                MsgBox sTemp
           End If
        Next
    Next
End Sub

Function MasterAltText(osh As Shape) As String

    Dim osl As Slide
    Dim oMasterShape As Shape
    Dim oLayout As CustomLayout
    
    ' Is this actually a placeholder?
    If Not osh.Type = msoPlaceholder Then
        MasterAltText = ""
    End If
    
    Set osl = osh.Parent
    Set oLayout = osl.CustomLayout
    
    For Each oMasterShape In oLayout.Shapes
        If oMasterShape.Type = msoPlaceholder Then
            If oMasterShape.PlaceholderFormat.Type _
              = osh.PlaceholderFormat.Type Then
                MasterAltText = oMasterShape.AlternativeText
                Exit Function
            End If
        End If
    Next

    MasterAltText = ""

End Function

Eu me aprofundei um pouco neste, e tenho que concluir que ver os slides mestres como "modelo" para cada slide está realmente quebrado.

Aparentemente , nenhuma das propriedades para tags ou texto alternativo definido em espaços reservados/quadros de texto em slides mestres são transportados para o slide baseado no mestre. Portanto, pensar que um código VBA pode fazer um loop sobre as formas com base na tag não é possível - a menos que as propriedades sejam definidas em cada slide.

Um hack que encontrei é usar as propriedades font e position. Dessa forma, é bastante simples destacar uma forma.

Algo junto

    For Each processPage In Application.ActivePresentation.Slides
       For Each shapeobj In processPage.Shapes
           If shapeobj.TextFrame.TextRange.Font.Italic <> 0 Then
               ' found some shape with ITALIC text
               ' do things to it
           End If
 
           ' check against a const with section position
           '  Global Const sectiontop as Double = 27.95
           ' 
           If Round(shapeobj.TextFrame2.TextRange.BoundTop, 2) = sectiontop Then
               ' found shape based on position
               ' do things to it
           End If
        Next  ' shap
    Next 'slide

Esta é a solução que funciona para mim, inspirada em Steve Rindsberg.

Eu faço um loop sobre as formas no layout mestre associado ao slide e, em seguida, construo um dicionário de texto alternativo, com base em algumas impressões digitais da forma. Usando a impressão digital (exemplo: tamanho da fonte, alinhamento, cor da fonte...) eu posso contornar esse texto alternativo e as tags não são transferidas do mestre para os slides.

Observei que isso só funciona com espaços reservados. As caixas de texto colocadas no slide mestre nem existem no contexto do slide, então o método aqui só funciona se o usuário não mexer na formatação.

''
''  inspired by
''  https://superuser.com/questions/1719032/powerpoint-slides-shapes-dont-seem-to-inherit-alternative-text-from-master/1719213#1719213
''
Sub updateSlide()


    Dim osl As Slide
    Dim d As Dictionary   ' need reference to MS scripting library
    
    Dim osh As Shape
    Dim sTemp As String
    Dim mykey As String
    
    Set d = Nothing
    
    ' Set d = New Dictionary
    
    ' loop over every slide
    For Each osl In ActivePresentation.Slides
        '
        ' make a dictionary of customtexts in the master
        '
        Set d = makedictionary(osl.CustomLayout)
    
        ' loop over shapes
        ' and find using properties like size / font...
        For Each osh In osl.Shapes
              mykey = makeKEY(osh)
              
              ' if found, do something with this shape.
              If Len(d(mykey)) > 0 Then
                If ActivePresentation.SectionProperties.Count < 1 Then
                   osh.TextFrame.TextRange.Text = "  -  "
                Else
                   ' can also replace with other presentation data.
                   ' 
                   osh.TextFrame.TextRange.Text = ActivePresentation.SectionProperties.Name(osl.sectionIndex)
                End If
              End If
        Next 'shapes
    Next 'slide
End Sub



''
''  make a fingerprint of a shape
''
Function makeKEY(oShape As Shape) As String
    ' return some variables from this one
    ' independent of position !
    ' this is like a "fingerprint" of the shape.
    With oShape.TextFrame.TextRange
        ' choose something that is UNIQUE to the shape
        makeKEY = .Font.Name & .ParagraphFormat.Alignment & .Font.Color & .Font.Italic
    End With
End Function


''
''  make a dictionary of shapes with an alternative text.
''  so we don't have to loop the same objects many times.
''

Function makedictionary(masterslide As CustomLayout) As Dictionary
    ' make a new dict
    Dim d As Dictionary
    Set d = New Dictionary
    Dim mSh As Shape
    
    For Each mSh In masterslide.Shapes
            If Len(mSh.AlternativeText) > 0 Then
               mykey = makeKEY(mSh)
               d(mykey) = mSh.AlternativeText
            End If
    Next
    
    Set makedictionary = d
    Set d = Nothing

End Function