Início / computer / Perguntas / 1718070
Accepted
Darren Bartrup-Cook
Asked: 2022-04-27 01:39:40 +0800 CST

Interlace (mesclar) dois intervalos derramados

  • 772

Estou tentando mesclar dois intervalos de derramamento de tamanhos iguais para que a primeira coluna do intervalo de derramamento A fique ao lado da primeira coluna do intervalo de derramamento B.

Estou perto de uma resposta, mas ao mesmo tempo tenho a sensação de que estou fazendo isso de maneira completamente errada.

Como exemplo:
Em A1digite a fórmula =SEQUENCE(3,2,1).
Em A5digite a fórmula=CHAR(SEQUENCE(3,2,65))

Isso fornecerá os dois intervalos abaixo. O resultado que procuro está nas linhas 9:11.
insira a descrição da imagem aqui

Meus pensamentos foram fazer isso com FILTERXML.

Isso une os dois intervalos e começa a construir a string xml (inserida em cell F1):

=LET(ColumnNum,COLUMN(A1#),
     FirstTable, A1#,
     SecondTable, A5#,
     PrefixA, "<a" & ColumnNum & ">",
     SuffixA, "</a" & ColumnNum & ">",
     PrefixB, "<b" & ColumnNum & ">",
     SuffixB, "</b" & ColumnNum & ">",
     xml, PrefixA & FirstTable & SuffixA &
          PrefixB & SecondTable & SuffixB,
     xml)

Isso finaliza o xml e retorna o intervalo final derramado.

=LET(StartCol,COLUMN(F1),
     xml,F1#,
     LastCol,StartCol+COLUMNS(xml)-1,
     finalxml,"<y>" & TEXTJOIN("",FALSE,IF(COLUMN(xml)=StartCol,"<x>","") & xml & IF(COLUMN(xml)=LastCol,"</x>","")) & "</y>",
     CHOOSE(SEQUENCE(,COLUMNS(xml)*2,1),
            FILTERXML(finalxml,"//x/a1"),
            FILTERXML(finalxml,"//x/b1"),
            FILTERXML(finalxml,"//x/a2"),
            FILTERXML(finalxml,"//x/b2")))

Isso funciona bem para dois intervalos de duas colunas, mas o número de colunas será alterado para que a CHOOSEinstrução precise ser atualizada manualmente a cada vez.

Existe uma maneira de fazer isso funcionar? Feliz em tomar LAMBDAsoluções, mas com medo de não poder usar as TEXTSPLITfunções do novo tipo.

microsoft-excel worksheet-function

2 respostas

  1. Em A9 coloque

    =INDEX($A$1#,0,INT((COLUMN()-1)/2)+1)

    e em B9 coloque

    =INDEX($A$5#,0,INT((COLUMN()-1)/2)+1)

    Agora copie A9:B9 para C9:D9.

    Se você tiver mais de duas colunas para intercalar, continue copiando a partir de E9 em intervalos de múltiplos de duas colunas.

    Além disso, se você tiver três ou mais intervalos de "fonte", apenas estenda a fórmula para o terceiro ou quarto intervalo e altere o "/2" para "/3" ou "/4" ou quantos mais intervalos você está trabalhando.

    EDIT: Não consegui pensar em uma maneira de analisar isso a partir de uma única fórmula de intervalo dinâmico no início. Infelizmente, o Excel não permite a junção de matrizes usando a sintaxe de matriz estática, por exemplo, {A1#, A5#} não é permitido. No entanto, a recente adição de MAKEARRAY e LAMBDA apresenta uma solução interessante:

    Solução de fórmula única!

    =LET(ranges, ($A$1#,$A$5#), rangecount, AREAS(ranges), rangetext, CELL("address",ranges), MAKEARRAY(ROWS(INDEX(ranges,0,0,1)),COLUMNS(INDEX(ranges,0,0,1))*rangecount, LAMBDA(r,cc, INDEX(($A$1#,$A$5#),r,INT((cc-1)/rangecount)+1,MOD(cc-1,rangecount)+1))))

    Infelizmente você não pode usar intervalos dentro da função lambda por algum motivo (um bug, eu acho). Tão mais fácil é definir seus intervalos duas vezes - um na instrução LET e uma vez como parte do INDEX.

    • 1
  2. Best Answer

    Aqui está uma fórmula mais fácil de escalar em comparação com a sua atual:

    =LET(t_count, 3, tables, (A1#,A5#,A9#), row_count, ROWS(INDEX(tables,0,0,1)), col_count, COLUMNS(INDEX(tables, 0, 0, 1)) * t_count, s, SEQUENCE(row_count, col_count, 0), INDEX(tables, INT(s / col_count) + 1, INT(MOD(s, col_count) / t_count) + 1, MOD(s, t_count) + 1))

    Ou a mesma fórmula dividida para uma melhor visão geral:

    =LET(
    t_count, 3, 
    tables, ( A1#, A5#, A9#), 
    row_count, ROWS(INDEX(tables, 0, 0, 1)), 
    col_count, COLUMNS(INDEX(tables, 0, 0, 1)) * t_count,  
    s, SEQUENCE(row_count, col_count, 0), 
    INDEX(
        tables, 
        INT(s / col_count) + 1, 
        INT(MOD(s, col_count) / t_count) + 1, 
        MOD(s, t_count) + 1
    )
 )

    Para modificar a fórmula, você só precisa atualizar t_counte listar todos os seus intervalos para tables.

    insira a descrição da imagem aqui

    • 1

relate perguntas