Início / computer / Perguntas / 1701402
Accepted
wyatt7613
Asked: 2022-01-26 21:12:23 +0800 CST

Excel VBA - If Statement Verificando se o valor está na matriz

  • 772

Eu tenho um monte de variáveis ​​que armazenei em uma matriz. Estou tentando usar uma instrução If Then para ver se o valor de uma célula específica está nessa matriz. Aqui está o meu código:

Dim Vars1 As Variant
Vars1 = Array("Stage 2", "Stage 3", "Stage 4", "Stage 5", "Stage 6", "Stage 7", "WIP Cleanup", 
"Road Test", "Test", "Test Cleanup", "In Bay Inspection", "In Bay Clean Up", "PDI", "PDI 
Cleanup", "Verify", "Complete", "Pictures", "Remove", "ECD", "Platform Install", "#N/A")
'Cuts special delivery parts for Line 3
For RowCounter = LastRow To 1 Step -1
    If InStr(1, Range("F" & RowCounter), "underslung", vbTextCompare) Then 'Underslung
        If Range("B" & RowCounter).Value = "FA Line 3" And Range("N" & RowCounter).Value = Vars1 Then
            Rows(RowCounter).EntireRow.Cut _
                Destination:=Sheets("FA3").Cells(Rows.Count, 1).End(xlUp).Offset(1, 0)
        End If
    End If
Next RowCounter

Eu não acho que o código está funcionando porque não está cortando e colando a linha. Como faço para obter a instrução if then para verificar e ver se o valor em "Range("N" & RowCounter)" está na matriz?

microsoft-excel microsoft-excel-2010

2 respostas

  1. Best Answer
    ...And Range("N" & RowCounter).Value = Vars1 Then

    Nesta parte do seu código, você está comparando um único valor a uma matriz. Você deve verificar se o valor está na matriz. Não sei de cabeça se existe uma função do Excel VBA que faz isso. Não é difícil escrever uma função que testa um valor em um array. Aqui está uma ideia,

    Option Explicit
Option Base 0

Function InArray(ByVal pstrVal As String, ByVal pvntArray As Variant) As Boolean

    Dim lngIdx As Long

    For lngIdx = 0 To UBound(pvntArray)
    
        If (pstrVal = VBA.CStr(pvntArray(lngIdx))) Then
            InArray = True
            Exit Function
        End If
    
    Next lngIdx

    InArray = False
End Function

    Para testar esta função,

    Sub Testing123()

    Dim Vars1 As Variant

    Vars1 = Array("Stage 2", "Stage 3", "Stage 4", "Stage 5", "Stage 6", "Stage 7", "WIP Cleanup", _
              "Road Test", "Test", "Test Cleanup", "In Bay Inspection", "In Bay Clean Up", "PDI", "PDI", _
              "Cleanup", "Verify", "Complete", "Pictures", "Remove", "ECD", "Platform Install", "#N/A")


    Debug.Print InArray("Testar", Vars1)
    Debug.Print InArray("Test", Vars1)
    Debug.Print InArray("In Bay Inspection", Vars1)
    Debug.Print InArray("Out Bay Inspection", Vars1)
End Sub

    Então, onde você tem sua condição, primeira linha na minha resposta, tente isso;

    ...And InArray(Range("N" & RowCounter).Value, Vars1) Then

    Espero que isto ajude

    njc

    • 1

  2. Outra maneira de contornar o problema é parar de descrever constantes como uma matriz. Descreva-o como

    Const Vars1 As String = "Stage 2" & vbTab & "Stage 3" & vbTab & "Stage 4" & vbTab _
    & "Stage 5" & vbTab & "Stage 6" & vbTab & "Stage 7" & vbTab _
    & "WIP Cleanup" & vbTab & "Road Test" & vbTab & "Test" & vbTab _
    & "Test Cleanup" & vbTab & "In Bay Inspection" & vbTab & "In Bay Clean Up" & vbTab _
    & "PDI" & vbTab & "PDI Cleanup" & vbTab & "Verify" & vbTab & "Complete" & vbTab _
    & "Pictures" & vbTab & "Remove" & vbTab & "ECD" & vbTab & "Platform Install" & vbTab & "#N/A"

    e use o mesmo InStr(...)que para a coluna F

    • 0

relate perguntas