Início / computer / Perguntas / 1691191
Accepted
bat_cmd
Asked: 2021-12-05 01:21:54 +0800 CST

Encurtar a fórmula "SE" do Excel?

  • 772

Esta fórmula funciona, mas é enorme:

=IF(X3=B2,K2,IF(X3=B3,K3,IF(X3=B4,K4,IF(X3=B5,K5,IF(X3=B6,K6,IF(X3=B7,K7,IF(X3=B8,K8,IF(X3=B9,K9,IF(X3=B10,K10,IF(X3=B11,K11,IF(X3=B12,K12,IF(X3=B13,K13,IF(X3=B14,K14,IF(X3=B15,K15,IF(X3=B16,K16,IF(X3=B17,K17,IF(X3=B18,K18,IF(X3=B19,K19,IF(X3=B20,K20,IF(X3=B21,K21))))))))))))))))))))

Aqui está o que está fazendo:

If X3 is the same as B2, show the contents of cell K2.
If X3 is the same as B3, show the contents of cell K3.
If X3 is the same as B4, show the contents of cell K4.
...etc etc etc all the way to...
If X3 is the same as B21, show the contents of cell K21.

Como B2:B21 é simplesmente uma coluna de células e K2:K21 também é apenas uma coluna de células, existe alguma maneira de encurtar a fórmula acima, para que não seja enorme?

Eu não sei como transformar isso em 2 intervalos de células B e células K.

Tentar algo assim não funciona: =IF(X3=B2:B21,K2:K21)

Porque dizer ao Excel para usar :é dizer para somar tudo, de B2 a B21 e K2 a K21. Gostaria de saber se há algum outro separador (não um :) que diz ao Excel para tratar cada célula individualmente em vez de adicioná-las?

Isso não funciona: =IF(X3=B2-B21,K2-K21)

Isso resulta em:#VALUE!

O problema é que, qualquer que seja o número da célula B, também deve ser correspondido com o número correspondente (horizontalmente) na célula K.

Obrigado antecipadamente a qualquer um que possa saber a resposta, que tenho certeza que é realmente simples se a funcionalidade existir no Excel.

microsoft-excel worksheet-function

3 respostas

  1. Best Answer

    Dependendo da sua versão do Excel, você pode usar XLOOKUP, VLOOKUPouINDEX/MATCH

    insira a descrição da imagem aqui

    =XLOOKUP($X$3,$B$2:$B$22,$K$2:$K$22,"")
=VLOOKUP($X$3,$B$2:$K$22,10,FALSE)
=INDEX($K$2:$K$22,MATCH($X$3,$B$2:$B$22))
    • 7

  2. =VLOOKUP(X3;B2:K21;columns(B2:K2))

    • Procure o valor de X3̈́ entre B2:B21, (primeira coluna do intervalo)
    • quando encontrado, selecione e exiba o valor B2:K2-colunas à direita.

    ... e Sim PROCV leva mais um argumento, que normalmente é revelado quando você digita o nome da função, ou mesmo quando você pressiona F1 (Ajuda).
    O valor padrão desse argumento é True, portanto, não é necessário digitá-lo nesse caso, mas se você precisar de correspondência exata no primeiro argumento, será necessário dizer 'False' aqui.

    Adicione IFERROR(...;"Not found")ao redor para exibir sua indicação de "nada encontrado".

    --- arquivo: exemplo.csv --- M4 usado em vez de X3 acima

    ,,,,,,,,,,,,
,1,,,,,,,,,A,,
,2,,,,,,,,,B,,"=PROCV(M4;B2:K21;10;Falso)"
,3,,,,,,,,,C,,5
,4,,,,,,,,,D,,
,5,,,,,,,,,E,,
,6,,,,,,,,,F,,
,7,,,,,,,,,G,,
,8,,,,,,,,,H,,
,9,,,,,,,,,eu,,
,10,,,,,,,,,J,,
,11,,,,,,,,,K,,
,12,,,,,,,,,L,,
,13,,,,,,,,,M,,
,14,,,,,,,,,N,,
,15,,,,,,,,,O,,
,16,,,,,,,,,P,,
,17,,,,,,,,,Q,,
,18,,,,,,,,,R,,
,19,,,,,,,,,S,,
,20,,,,,,,,,T,,
,21,,,,,,,,,U,,

    • 2

  3. No mínimo, podemos nos livrar dos parênteses extras usando IFS:

    =IFS(X3=B2,K2,X3=B3,K3,X3=B4,K4,X3=B5,K5,X3=B6,K6,X3=B7,K7,X3=B8,K8,X3=B9,K9,X3=B10,K10,X3=B11,K11,X3=B12,K12,X3=B13,K13,X3=B14,K14,X3=B15,K15,X3=B16,K16,X3=B17,K17,X3=B18,K18,X3=B19,K19,X3=B20,K20,X3=B21,K21)

    Esta é uma simplificação geral que funciona sempre que você tem funções aninhadas IFcomo essa, mesmo que as diferentes condições e resultados não tenham nada em comum.

    No entanto, no seu caso, há um padrão simples para as condições e podemos simplificar ainda mais sua expressão, por exemplo, usando using XLOOKUP:

    =XLOOKUP(X3, B2:B21, K2:K21)

    Observe que XLOOKUPé um novo recurso do Excel 2021 e pode não funcionar em versões mais antigas do Excel. Para essas versões, você pode obter o mesmo resultado usando INDEXe MATCH, como em:

    =INDEX(K2:K21, MATCH(X3, B2:B21, 0))

    ou usando VLOOKUP:

    =VLOOKUP(X3, B2:K21, COLUMNS(B2:K2), FALSE)

    Onde suportado, no entanto, XLOOKUPé provavelmente a solução mais conveniente neste caso, e também suporta vários parâmetros adicionais que permitem especificar como a pesquisa é feita e o que fazer caso nenhuma correspondência exata seja encontrada.

    (Observe também que as soluções INDEX/ MATCHe VLOOKUPterão de ser ajustadas, ou podem não funcionar, se você quiser, por exemplo, pesquisar ao longo de uma linha em vez de uma coluna ou retornar um valor de uma coluna que está à esquerda da pesquisa deve funcionar em todos os casos, o que IMO é uma boa razão para preferi-lo sempre que possível. XLOOKUP)

    • 1

relate perguntas