Início / computer / Perguntas / 1687298
Accepted
Unapedra
Asked: 2021-11-14 07:20:16 +0800 CST

Como alterar o idioma de entrada apenas para o teclado emoji do Windows

  • 772

Eu tenho o idioma do meu sistema definido como espanhol, bem como o idioma de entrada do teclado. No entanto, estou acostumado a pesquisar emojis em todos os aplicativos que permitem fazer isso em inglês (Telegram, Twitter, WhatsApp...).

Pelo que vi, o teclado emoji no Windows 10 (pressione as teclas: Win + . ) permite pesquisar emojis, mas apenas usando o idioma do sistema. Portanto, se eu tentar pesquisar por "olhos", as sugestões ficarão vazias, pois "olhos" não existe em espanhol, então o que uso para pesquisar esse emoji específico em todos os outros aplicativos não funciona com essa pesquisa de teclado de emoji.

Mesmo no meu laptop de trabalho, onde tenho o idioma do sistema configurado em inglês, tenho que usar palavras diferentes do meu laptop pessoal, embora esteja usando o mesmo aplicativo devido ao idioma do sistema diferente.

Existe alguma maneira de especificar que quero pesquisar emojis usando um idioma específico e não o idioma do meu sistema? Ou talvez usando ambos: o que eu especifico e o idioma do meu sistema como padrão se nada for encontrado?

Este é o único aplicativo afetado por esse problema, portanto, mexer nas configurações globais do sistema não seria uma opção.

Muito obrigado.

windows keyboard

1 respostas

  1. Best Answer

    Já fiz alguns testes com o painel emoji, e está muito problemático.

    Primeiro, qualquer alteração no idioma do sistema fará com que ele seja encerrado imediatamente, portanto, as alterações no idioma precisam ser feitas antes de iniciá-lo.
    Segundo, não há como iniciá-lo, exceto pelo teclado, nem detectar programaticamente quando ele é executado ou quando termina.

    Minha solução (que funciona no meu ambiente) é um script que intercepta Win+ ;e faz o seguinte (para usar Win+ .mude a linha com $#;::para $#.::):

    • Conserva a janela ativa atual e o idioma do sistema
    • Altera o idioma do sistema para inglês dos EUA
    • Emite a chave Win+ ;(não interceptada desta vez)
    • Aguarda que a janela ativa anterior se torne ativa novamente (o que significa que o painel de idiomas foi encerrado)
    • Redefine o idioma do sistema para o que era.

    A ferramenta que usei é o AutoHotkey gratuito .

    No script abaixo, a seção entre "start debug" e "end debug" é apenas para sua conveniência e deve ser excluída quando tudo funcionar.

    curlang := 0

; >>>> start debug : function keys for testing

; https://docs.microsoft.com/en-us/previous-versions/ms957130(v=msdn.10)
F7:: SetDefaultKeyboardLang(0x0409)    ; english usa
F8:: SetDefaultKeyboardLang(0x040c)    ; french
F9:: SetDefaultKeyboardLang(0x0415)    ; polish
F12::                                  ;- show current keyboard language
SetFormat, Integer, H
curlang:= DllCall("user32.dll\GetKeyboardLayout", "UInt", ThreadId, "UInt")
msgbox,Language identifier=%curlang%
curlang := 0
Return

; <<<< end debug

$#;::                                  ; intercept win+;
WinGet, activewin, ID, A
curlang:= DllCall("user32.dll\GetKeyboardLayout", "UInt", ThreadId, "UInt")
ActiveHwnd := WinExist("A")
SetDefaultKeyboardLang(0x0409)         ; english usa
Sleep, 100
Send, {LWin down}`;{LWin up}           ; semi-colon needs to be escaped
curlang := 0
SetTimer, waitactive, 200
return

waitactive:
if WinActive("ahk_id" activewin) {
  SetDefaultKeyboardLang(curlang)
  SetTimer, waitactive, Off
}
return

;-------------------------------
; https://autohotkey.com/boards/viewtopic.php?f=6&t=18519
SetDefaultKeyboardLang(LocaleID){
    Static SPI_SETDEFAULTINPUTLANG := 0x005A, SPIF_SENDWININICHANGE := 2    
    Lan := DllCall("LoadKeyboardLayout", "Str", Format("{:08x}", LocaleID), "Int", 0)
    VarSetCapacity(binaryLocaleID, 4, 0)
    NumPut(LocaleID, binaryLocaleID)
    DllCall("SystemParametersInfo", "UInt", SPI_SETDEFAULTINPUTLANG, "UInt", 0, "UPtr", &binaryLocaleID, "UInt", SPIF_SENDWININICHANGE) 
    WinGet, windows, List
    Loop % windows {
        PostMessage 0x50, 0, % Lan, , % "ahk_id " windows%A_Index%
    }
}

    Depois de instalar o AutoHotKey, coloque o texto acima em um .ahkarquivo e clique duas vezes nele para testar. Você pode parar o script clicando com o botão direito do mouse no ícone verde H na barra de bandeja e escolhendo Sair. Para executá-lo no login, coloque-o no grupo Startup em
    C:\Users\USER-NAME\AppData\Roaming\Microsoft\Windows\Start Menu\Programs\Startup.

    Documentação útil do AutoHotkey:

    • 1

relate perguntas