Início / computer / Perguntas / 1664983
Accepted
RoyalGoose
Asked: 2021-07-28 05:59:11 +0800 CST

Como interpolar valores no Excel

  • 772

Eu tenho duas mesas. O primeiro contém taxas condicionais indicativas para um número específico de dias (títulos de coluna)

Encontro 1 dia 7 dias 14 dias 30 dias 90 dias
11.01.2021 4,36 4,36 4h30 4,49 4,64
12.01.2021 4,32 4,34 4,36 4,48 4,63
13.01.2021 4,25 4,32 4,34 4,43 4,60
14.01.2021 4,26 4,35 4,35 4,36 4,58
15.01.2021 4,33 4,35 4,37 4,34 4,57

E a segunda tabela na qual preciso calcular a taxa real para um determinado número de dias

Encontro Dias Avaliar
12.01.2021 21 ?
13.01.2021 74 ?
15.01.2021 40 ?

Como você pode ver, taxas condicionais são fornecidas para alguns dias e taxas reais para outros. Entre outras coisas, as taxas condicionais são dadas para cada dia e as taxas reais apenas em alguns deles. Como posso calcular essa taxa? Eu vejo o uso de interpolação linear aqui, por exemplo - se o número real de dias é 21, então a taxa condicional mais próxima é dada para 14 dias e eu preciso extrapolar esse valor vários dias no futuro. Eu li sobre =forecast, mas não faz o que eu preciso. Existe uma função no Excel que me ajude a fazer isso ou preciso escrever um script VBA para isso?

microsoft-excel worksheet-function

2 respostas

  1. precisamos obter uma proporção de onde os dias param entre o ponto de ajuste e multiplicar essa proporção pela diferença entre os valores superior e inferior e, em seguida, adicionar o valor inferior a esse resultado.

    Uma etapa que deve ocorrer é alterar os cabeçalhos para o número real.

    No OFFICE 365 podemos usar LET para simplificar as etapas:

    =LET(head,$B$1:$F$1,
         lkp,B7,
         rng,$B$2:$F$4,
         dt,$A$2:$A$4,
         rw,INDEX(rng,MATCH(A7,dt,0),0),
         mtch,MATCH(lkp,head),
         mtchp1,mtch+1,
         fst,INDEX(head,,mtch),
         scd,INDEX(head,,mtchp1),
         fct,(lkp-fst)/(scd-fst),
          vlue1,INDEX(rw,,mtch),
          vlue2,INDEX(rw,,mtchp1),
          (vlue2-vlue1)*fct+vlue1)

    insira a descrição da imagem aqui

    sem deixar:

    =(INDEX(INDEX($B$2:$F$4,MATCH(A7, $A$2:$A$4,0),0),, MATCH(B7, $B$1:$F$1)+1)- INDEX(INDEX($B$2:$F$4,MATCH(A7, $A$2:$A$4,0),0),, MATCH(B7, $B$1:$F$1)))* ((B7- INDEX($B$1:$F$1,, MATCH(B7, $B$1:$F$1)))/( INDEX($B$1:$F$1,, MATCH(B7, $B$1:$F$1)+1)- INDEX($B$1:$F$1,, MATCH(B7, $B$1:$F$1))))+ INDEX(INDEX($B$2:$F$4,MATCH(A7, $A$2:$A$4,0),0),, MATCH(B7, $B$1:$F$1))

    Como você pode ver, torna-se muito pesado e difícil de gerenciar.

    insira a descrição da imagem aqui

    Outro método com o LET é usar FORECAST.LINEAR em vez de math para obter a resposta depois de obter os x e y de início e fim:

    =LET(head,$B$1:$F$1,
         lkp,B7,
         rng,$B$2:$F$4,
         dt,$A$2:$A$4,
         rw,INDEX(rng,MATCH(A7,dt,0),0),
         mtch,MATCH(lkp,head),
         mtchp1,mtch+1,
         fst,INDEX(head,,mtch),
         scd,INDEX(head,,mtchp1),
          vlue1,INDEX(rw,,mtch),
          vlue2,INDEX(rw,,mtchp1),
          FORECAST.LINEAR(lkp,CHOOSE({1,2},vlue1,vlue2),CHOOSE({1,2},fst,scd)))

    insira a descrição da imagem aqui

    • 3
  2. Best Answer

    insira a descrição da imagem aqui

    Escritório 365:

    =FORECAST.LINEAR(B7,
 INDEX(B2:F2,MATCH(B7,$B$1:$F$1,1)):INDEX(B2:F2,MATCH(B7,$B$1:$F$1,1)+1),
 INDEX($B$1:$F$1,MATCH(B7,$B$1:$F$1,1)):INDEX($B$1:$F$1,MATCH(B7,$B$1:$F$1,1)+1))

    De Interpolar com Excel

    Surpreendentemente, a interpolação linear é bastante difícil de fazer no Excel.

    Isso usa a função de previsão do Excel =FORECAST(x,known_y's,known_x's).

    O =INDEXe =MATCHescolha os dois pontos relevantes em known_y'se known_x's.

    Isso funcionará no Excel 2007, mas =FORECAST.LINEARdeve ser alterado para =FORECAST(depreciado em breve).

    • 2

relate perguntas