VBA Excel - Verificando a semelhança de texto na mesma coluna

Isso é feito facilmente com formatação condicional.

1. Faça a célula ativa J2
2. Abra a caixa de diálogo de formato condicional
3. SelecionarUse Formula for Conditional Formatting
4. Digite a fórmula =$J2<>$J1e defina a borda como quiser
5. Ajuste as Applies Tocélulas para fazer com que o sublinhado vá para as células desejadas

Se você estiver bem com uma borda preta fina, a formatação condicional funcionará. Se você realmente deseja uma borda preta grossa , precisará do código de evento VBA, pois não pode modificar a espessura de uma borda na propriedade de borda de formatação condicional.

Para inserir esta Macro acionada por evento, clique com o botão direito do mouse na guia da planilha. Selecione "Visualizar código" no menu suspenso do botão direito. Em seguida, cole o código abaixo na janela que se abre.

Option Explicit
Private Sub Worksheet_Change(ByVal Target As Range)
    Dim dataRange As Range
    Dim v As Variant, I As Long
    
Set dataRange = Range(Cells(2, 2), Cells(100, 10)) 'change as needed
If Not Intersect(Target, dataRange) Is Nothing Then
    With dataRange
        v = .Columns(9)
        For I = 1 To UBound(v) - 1
            If v(I, 1) <> v(I + 1, 1) Then
                With .Rows(I).Borders(xlEdgeBottom)
                    .LineStyle = xlContinuous
                    .Color = vbBlack
                    .Weight = xlThick
                End With
            Else
                .Rows(I).Borders(xlEdgeBottom).LineStyle = xlNone 'or whatever you want for the default border
            End If
        Next I
    End With
End If
End Sub

Editar: para ter uma macro autônoma e não acionada por evento,
entre em um módulo regular,
você pode chamá-lo de outra macro, acioná-lo com um botão ou iniciá-lo manualmente

Option Explicit
Sub LineIT()
    Dim WS As Worksheet
    Dim dataRange As Range
    Dim v As Variant, I As Long
    
Set WS = ThisWorkbook.Worksheets("Sheet4") 'or whatever workbook and worksheet the table you which to process is located

With WS
    Set dataRange = Range(.Cells(2, 1), Cells(.Rows.Count, 10).End(xlUp)) 'change as needed
    With dataRange
        v = .Columns(10)
        For I = 1 To UBound(v) - 1
            If v(I, 1) <> v(I + 1, 1) Then
                With .Rows(I).Borders(xlEdgeBottom)
                    .LineStyle = xlContinuous
                    .Color = vbBlack
                    .Weight = xlThick
                End With
            Else
                .Rows(I).Borders(xlEdgeBottom).LineStyle = xlNone 'or whatever you want for the default border
            End If
        Next I
    End With
End With
End Sub