Início / computer / Perguntas / 1653458
Accepted
Bob Weeks
Asked: 2021-06-04 06:23:57 +0800 CST

Excel, crie uma nova janela com as mesmas configurações

  • 772

Ao criar uma nova janela para uma pasta de trabalho existente, algumas configurações não são transferidas para a nova janela. O mais importante para mim são as configurações de painel, linha e coluna congelados, juntamente com a visibilidade das linhas de grade. Outros relataram outras configurações não sendo observadas. Alguns descreveram uma solução usando macros, mas isso parece uma complexidade extra para algo que espero ter uma solução simples.

Isso ocorre ao usar a opção Exibir | Novo comando de janela em uma pasta de trabalho existente.

microsoft-excel

1 respostas

  1. Best Answer

    É assim que o Excel funciona e pode ser um bug ou um "recurso". Não pode ser resolvido usando a GUI do Excel, portanto, é necessária uma macro VBA.

    O artigo Gridlines & Freeze Panes Settings Lost in New Window – How to Fix It descreve o problema e contém a solução como uma macro VBA que faz o seguinte:

    • Criar a nova janela
    • Percorre todas as planilhas na nova janela e aplica o seguinte da janela original: Linhas de grade, Congelar painéis e Títulos.
    • Ativa a folha original na janela original e nova
    • Organize as janelas na exibição de tela dividida vertical lado a lado
    • Role até a guia ativa na pasta de trabalho para poder visualizá-la.

    Caso o artigo desapareça no futuro, aqui está o código VBA:

    Sub New_Window_Preserve_Settings()
'Create a new window and apply the grid line settings
'for each sheet.

Dim ws As Worksheet
Dim i As Long
Dim iWinCnt As Long
Dim bGrid As Boolean
Dim bPanes As Boolean
Dim bHeadings As Boolean
Dim iSplitRow As Long
Dim iSplitCol As Long
Dim iActive As Long
Dim iZoom As Long
Dim sSep As String

  Application.ScreenUpdating = False

  'Store the active sheet
  iActive = ActiveSheet.Index

  'Create new window
  ActiveWindow.NewWindow
  iWinCnt = ActiveWorkbook.Windows.Count
  
  'Set the separator based on the version of Excel
  'Office 365 now using a dash
  If InStr(":", ActiveWorkbook.Name) > 0 Then
    sSep = ":"
  Else
    sSep = "  -  "
  End If
  
  'Loop through worksheets of original workbook
  'and apply grid line settings to each sheet.
  For Each ws In ActiveWorkbook.Worksheets
    Windows(ActiveWorkbook.Name & sSep & "1").Activate
    ws.Activate
    
    'Store the properties
    bGrid = ActiveWindow.DisplayGridlines
    bHeadings = ActiveWindow.DisplayHeadings
    iZoom = ActiveWindow.Zoom
    
    'Get freeze panes
    bPanes = ActiveWindow.FreezePanes
    If bPanes Then
       iSplitRow = ActiveWindow.SplitRow
       iSplitCol = ActiveWindow.SplitColumn
    End If
    
    'Activate the new window and sheet in loop
    Windows(ActiveWorkbook.Name & sSep & iWinCnt).Activate
    Worksheets(ws.Index).Activate
    
    'Set properties
    With ActiveWindow
      .DisplayGridlines = bGrid
      .DisplayHeadings = bHeadings
      .Zoom = iZoom
      If bPanes Then
        .SplitRow = iSplitRow
        .SplitColumn = iSplitCol
        .FreezePanes = True
      End If
    End With
  Next ws
    
  'Activate original active sheet for the new window
  Worksheets(iActive).Activate
  
  'Activate the original active sheet for the original window
  Windows(ActiveWorkbook.Name & sSep & "1").Activate
  Worksheets(iActive).Activate
  
  'Split Screen View (optional)
  'The following section can be commented out if you don't want split screen.
  
    'Turn screen updating on for split screen
    Application.ScreenUpdating = True
     
    For i = iWinCnt To 1 Step -1
      Windows(ActiveWorkbook.Name & sSep & i).Activate
    Next i
    
    'Split view side-by-side vertical
    ActiveWorkbook.Windows.Arrange ArrangeStyle:=xlVertical
    
    'Scroll to active tab in original window
    ActiveWindow.ScrollWorkbookTabs Position:=xlFirst
    ActiveWindow.ScrollWorkbookTabs Sheets:=iActive
    
    'Scroll to active tab in new window
    Windows(ActiveWorkbook.Name & sSep & iWinCnt).Activate
    DoEvents
    ActiveWindow.ScrollWorkbookTabs Position:=xlFirst
    ActiveWindow.ScrollWorkbookTabs Sheets:=iActive
  
End Sub

    O artigo também contém uma macro VBA para fechar as janelas adicionais, para que elas não sejam salvas por engano e substituam a pasta de trabalho original:

    Sub Close_Additional_Windows()
'Close additional windows and maximize original

Dim i As Long
Dim sSep As String

  'Set the separator based on the version of Excel
  'Office 365 now using a dash
  If InStr(":", ActiveWorkbook.Name) > 0 Then
    sSep = ":"
  Else
    sSep = "  -  "
  End If
  
  If ActiveWorkbook.Windows.Count > 1 Then
    For i = ActiveWorkbook.Windows.Count To 2 Step -1
      Windows(ActiveWorkbook.Name & sSep & i).Close
    Next i
  End If
  
  Windows(ActiveWorkbook.Name).WindowState = xlMaximized

End Sub

    O artigo também contém uma seção sobre como instalar as macros em sua pasta de trabalho, caso você nunca tenha trabalhado com VBA.

    • 2

relate perguntas