Início / coding / Perguntas / 79471366
Accepted
DavidS
Asked: 2025-02-27 08:40:52 +0800 CST

Usando Perl Regex, como posso capturar a posição dos hifens em uma palavra hifenizada?

  • 772

Estou tentando capturar a posição de todos os hifens em uma palavra hifenizada, para que eu possa carregar um hash com a posição desses hifens (no texto, não na palavra). No momento, estou tentando um grupo de captura dentro de um grupo sem captura... mas ele está capturando apenas o último hífen.

my $word           = shift (@_);
my $word_start_pos = shift (@_);
my $text           = shift (@_);

my $dash_pos  = 0;
my $exp       = 0;
my $pos       = 0;
my $test_char = '';
   
if ($word =~ /^(?:[\p{L&}0-9\.\'\/]{1,}([\-])){7,}[\p{L&}0-9\.\'\/]{1,}$/) {
   foreach $exp (1..$#-) {
      $pos = $-[$exp];
      $dash_pos = $word_start_pos + $pos;
      $test_char = substr($text, $dash_pos, 1);
      if ($test_char =~ /^[\-]$/) {
         &load_changes('-', $dash_pos, 'Dash', ' ', 'Replace');
      }
   }
}
regex

3 respostas

  1. Best Answer
    push @pos, $-[0] while /-/g;

    Demonstração:

    $ perl -Mv5.14 -ne'my @pos; push @pos, $-[0] while /-/g; say "@pos";'
abc-de-fgh
3 6
-----
0 1 2 3 4

    No contexto, você poderia substituir

    foreach $exp (1..$#-) {
   $pos = $-[$exp];
   ...
}

    com

    while ( $word =~ /-/g ) {
   my $pos = $-[0];
   ...
}
    • 3

  2. Não vejo nenhum benefício em usar regexes para essa tarefa. Não é uma ferramenta que seja adequada para o trabalho. Aqui estão duas abordagens alternativas que são muito mais simples e eficientes:

    #!/usr/bin/env perl    

use strict;
use warnings;
use 5.010;

my $str = 'Reg-ex-es are total over-kill for this search-task.';

say '--- using index ---';

my $last = -1;
while (my $pos = index($str, '-', $last)) {
  last if $pos == -1;
  say $pos;
  $last = $pos + 1;
} 

say '--- using split ---';
my @chars = split '', $str;
for my $pos (0 .. $#chars) {
  say $pos if $chars[$pos] eq '-';
}

    Saída:

    --- using index ---
3
6
24
45
--- using split ---
3
6
24
45

    (Observe que as posições são baseadas em 0.)

    • 1

  3. Provavelmente não é a melhor ideia redefinir manualmente a posvariável. Basicamente, o que isso faz é fazer uma correspondência global pular para frente e para trás em uma string em vez de processá-la do começo ao fim.

    Este é um uso direto dos arrays @-e @+, que funcionam em conjunto com o posvalor.

    perldoc -v @-
@-      This array holds the offsets of the beginnings of the last
        successful match and any capture buffers it contains. 
        <cut>

perldoc -v @+
@+      This array holds the offsets of the ends of the last successful
        match and any matching capture buffers that the pattern
        contains.
        <cut>

perldoc -f pos
pos     Returns the offset of where the last "m//g" search left off for
        the variable in question ($_ is used when the variable is not
        specified).
        <cut>

    @+é equivalente ao posvalor de cada partida. Parece que você quer o @-valor.

    Aqui está o código...

    #!/usr/bin/perl

my $s = q"here-is-a-string-with-a-lot-of-hyphens";
my @hyphenStack;

while($s=~/-/g){
  push(@hyphenStack, $-[0]);
}
for(@hyphenStack){
  print "$_\n";
}

    A saída se parece com isso...

    $ perl find.hyphens.pl
4
7
9
16
21
23
27
30

    Jogou golfe com 54 caracteres

    $ perl -e 'for(@ARGV){print"\n$_\n";while(/-/g){print "$-[0]\n"}}' test-1 test-2 test-3-4-5-6 here-is-a-string-with-a-lot-of-hyphens "here is a string with-spaces-and-hyphens"

test-1
4

test-2
4

test-3-4-5-6
4
6
8
10

here-is-a-string-with-a-lot-of-hyphens
4
7
9
16
21
23
27
30

here is a string with-spaces-and-hyphens
21
28
32
    • -1

relate perguntas