Início / coding / Perguntas / 79415379
Accepted
Konchog
Asked: 2025-02-06 00:00:56 +0800 CST

Calculando valores derivados

  • 772

Estou tentando descobrir como escrever uma fórmula intuitiva no Planilhas Google que, dadas duas tabelas (de booleanos) com dimensões AxB, CxB, uma gere a tabela correlacionada CxAseguindo o booleano OR.

Que fórmula pode ser usada para gerar a tabela CxA? Eu definitivamente quero que a tabela seja preenchida usando uma fórmula de célula única.

Tenho pensado em usar map, byrow, bycolou scan, mas cada vez que começo me perco na matriz.

As tabelas abaixo destacam o caso em que Ré verdadeiro para [a,e]; [1,2,3,6]são verdadeiros para a; e [3,4,6]são verdadeiros para e:- portanto [1,2,3,4,6]são verdadeiros para R.

AxB R B G E
um 1 0 0 0
b 0 0 0 1
c 0 1 1 0
e 0 1 0 0
e 1 1 0 0
CxB 1 2 3 4 5 6
um 1 1 1 0 0 1
b 0 0 1 0 1 0
c 0 1 0 1 1 0
e 1 1 0 1 1 0
e 0 0 1 1 0 1
CxA 1 2 3 4 5 6
R 1 1 1 1 0 1
B 1 1 1 1 1 1
G 0 1 0 1 1 0
E 0 0 1 0 1 0
google-sheets

4 respostas

  1. No C10 você pode tentar:

    =let(
head_rbgk,C2:F2,
tab_rbgk,C3:F7,
tab_123456,K3:P7,
map(B10:B13,lambda(x,
bycol(filter(tab_123456,filter(tab_rbgk,head_rbgk=x)),lambda(y,ifna(--or(y)))))))
    • 3

  2. Outra abordagem usando as virtudes do MAKEARRAY:

    =MAKEARRAY(COUNTA(B1:E1),COUNTA(B8:G8),LAMBDA(r,c,
ARRAYFORMULA(IF(SUM(INDEX(B2:E6,,r)*INDEX(B9:G13,,c)),1,0))))
    • 3
  3. Best Answer

    Você pode tentar:

    =index(sign(mmult(transpose(C3:F7),K3:P7)))

    insira a descrição da imagem aqui

    • 3

  4. Use map(), filter()e bycol(), assim:

    =map(transpose(C2:F2), lambda(key, let( 
  col, filter(C3:F7, key = C2:F2), 
  matches, filter(K3:P7, col), 
  bycol(matches, lambda(m, n(or(m)))) 
)))

    captura de tela

    Veja map() , filter() e bycol() .

    • 1

relate perguntas