Como imprimir '' em vez de '

Como uma string vazia ''é equivalente a nullno Oracle, neste caso você pode evitar o problema substituindo tabulação/nova linha por nulo; então, em vez disso:

WHEN DATA_TYPE LIKE ''%CHAR%''
THEN ''REPLACE(REPLACE(t.'' || COLUMN_NAME || '', CHR(13), ''''), CHR(10), '''') AS '' || COLUMN_NAME

faça isso:

WHEN DATA_TYPE LIKE ''%CHAR%''
THEN ''REPLACE(REPLACE(t.'' || COLUMN_NAME || '', CHR(13), null), CHR(10), null) AS '' || COLUMN_NAME

Você não precisa usar SQL dinâmico aqui, pois pode consultar estaticamente o dicionário de dados - o esquema de destino/nome da tabela são variáveis ​​aqui, não identificadores:

DECLARE
  v_owner VARCHAR2(50) := 'LFS_SURVEY'; -- Replace with your schema/owner name
  v_table_name VARCHAR2(50) := 'LFS_FAMILY_TAB'; -- Replace with your table name
  v_rp_ids VARCHAR2(100) := '2030, 2031'; -- Replace with your RP_ID values
  v_columns CLOB;
  v_query   CLOB;
BEGIN
  -- Get all column names with transformations based on data type
  SELECT RTRIM(XMLAGG(XMLELEMENT(e, 
    CASE 
      WHEN COLUMN_NAME = 'F_M_ID'
      THEN 'TO_CHAR(t.F_M_ID) AS F_M_ID'
      WHEN DATA_TYPE LIKE '%CHAR%'
      THEN 'REPLACE(REPLACE(t.' || COLUMN_NAME || ', CHR(13), null), CHR(10), null) AS ' || COLUMN_NAME
      ELSE 't.' || COLUMN_NAME 
    END || ', ').EXTRACT('//text()') ORDER BY COLUMN_ID).GETCLOBVAL(), ', ') 
  INTO v_columns
  FROM ALL_TAB_COLUMNS 
  WHERE TABLE_NAME = v_table_name
  AND OWNER = v_owner;
  DBMS_OUTPUT.PUT_LINE(v_columns);
END;
/

Com uma tabela fictícia criada como:

create table LFS_FAMILY_TAB (f_m_id number, foo date, bar varchar2(30))

que produz:

TO_CHAR(t.F_M_ID) AS F_M_ID, t.FOO, REPLACE(REPLACE(t.BAR, CHR(13), null), CHR(10), null) AS BAR

violino

E isso é funcionalmente o mesmo que

TO_CHAR(t.F_M_ID) AS F_M_ID, t.FOO, REPLACE(REPLACE(t.BAR, CHR(13), ''), CHR(10), '') AS BAR

Se você realmente quiser ''( nullou talvez tiver que lidar com outros literais de texto), você pode usar XMLTable, que não escapa de entidades como extract(e XMLQuery):

DECLARE
  v_owner VARCHAR2(50) := 'LFS_SURVEY'; -- Replace with your schema/owner name
  v_table_name VARCHAR2(50) := 'LFS_FAMILY_TAB'; -- Replace with your table name
  v_rp_ids VARCHAR2(100) := '2030, 2031'; -- Replace with your RP_ID values
  v_columns CLOB;
  v_query   CLOB;
BEGIN
  -- Get all column names with transformations based on data type
  SELECT RTRIM(x.str, ', ')
  INTO v_columns
  FROM (
    SELECT XMLELEMENT(r, XMLAGG(XMLELEMENT(e, 
      CASE 
        WHEN COLUMN_NAME = 'F_M_ID'
        THEN 'TO_CHAR(t.F_M_ID) AS F_M_ID'
        WHEN DATA_TYPE LIKE '%CHAR%'
        THEN 'REPLACE(REPLACE(t.' || COLUMN_NAME || ', CHR(13), ''''), CHR(10), '''') AS ' || COLUMN_NAME
        ELSE 't.' || COLUMN_NAME 
      END || ', ') ORDER BY COLUMN_ID)) AS xmlx
    FROM ALL_TAB_COLUMNS
    WHERE TABLE_NAME = v_table_name
    AND OWNER = v_owner
  ) atc
  CROSS JOIN XMLTABLE(
    '/R'
    PASSING atc.xmlx
    COLUMNS str CLOB PATH '.'
  ) x;
  DBMS_OUTPUT.PUT_LINE(v_columns);
END;
/

que para a mesma tabela fictícia gera:

TO_CHAR(t.F_M_ID) AS F_M_ID, t.FOO, REPLACE(REPLACE(t.BAR, CHR(13), ''), CHR(10), '') AS BAR

violino

A propósito, seu código original produz ', mas isso é apenas uma aspa com escape de entidade '. Se você quisesse duas '', precisaria de ainda mais em seu código:

WHEN DATA_TYPE LIKE ''%CHAR%''
THEN ''REPLACE(REPLACE(t.'' || COLUMN_NAME || '', CHR(13), ''''''''), CHR(10), '''''''') AS '' || COLUMN_NAME

Mas isso ''não resolveria o problema, mesmo que você desfaça o escape manualmente dessas entidades.

O Oracle representa 4 aspas simples consecutivas como uma aspa simples. Então, talvez a maneira mais legível ao construir algum sql dinâmico seria declarar uma variável de aspas simples
sq VARCHAR2(1) := '''';
como abaixo:

DECLARE
  v_table_name VARCHAR2(50) := 'LFS_FAMILY_TAB'; 
  v_query   CLOB;
  sq   VARCHAR2(1) := '''';  -- 4 single quotes are represented as one single quote
BEGIN
  v_query := 'SELECT '|| Chr(10) || 
             '   CASE WHEN COLUMN_NAME = ' || sq || sq || 'F_M_ID' || sq || sq || Chr(10) ||
             '       THEN ' || sq || sq || 'TO_CHAR(t.F_M_ID)' || sq || sq || ' AS F_M_ID ' || Chr(10) ||
             '   ELSE t.' || sq || 'COLUMN_NAME ' || sq || Chr(10) || 
             '   END as SOME_ALIAS ' || Chr(10) || 
             'FROM ' || v_table_name || Chr(10) ||
             '      ... ';
  dbms_output.put_line(v_query);           
END;
/

--  R e s u l t : 
SELECT 
   CASE WHEN COLUMN_NAME = ''F_M_ID''
       THEN ''TO_CHAR(t.F_M_ID)'' AS F_M_ID 
   ELSE t.'COLUMN_NAME '
   END as SOME_ALIAS 
FROM LFS_FAMILY_TAB
      ... 

OBSERVAÇÃO:
Dessa forma, você pode inserir sq (ou dois, três deles) em qualquer lugar da string e manter o código legível e sustentável...

Por que 4 para obter 1?

--  Some text enclosed within quotes and containing a single quote like 
--  "father's house"
--  requires duplication of single quote to result as one single quote
Select '... father''s house ...' as SAMPLE From Dual;

-- if you remove all other text but the single quotes
-- you will end up with 2 outer enclosing single quotes and 2 inner ones resulting as just one:
Select '''' as SAMPLE From Dual;

violino

Existem algumas técnicas pl/sql que simplificarão seu código e reduzirão as chances de encontrar problemas como o seu. Como outros indicaram, isso EXECUTE IMMEDIATEnão é necessário neste caso em particular, mas se você escolher fazer isso de qualquer maneira, aqui estão algumas dicas.

citação alternativa também conhecida como sintaxe Q-quote

Isso permite que você use outro delimitador de string diferente de aspas simples - eliminando assim a necessidade de escape de aspas ( docs )

Exemplo:

BEGIN
    -- the "old way"
    dbms_output.put_line('this is a quote: '', and here are 2 quotes: ''''');
    -- alternative quoting
    dbms_output.put_line(q'!this is a quote: ', and here are 2 quotes: ''!');
END;
/  
this is a quote: ', and here are 2 quotes: ''
this is a quote: ', and here are 2 quotes: ''


PL/SQL procedure successfully completed.

use variáveis ​​de ligação, não concatenação

Conectar valores de variáveis ​​em pl/sql e sql não é uma boa prática. Isso torna o código vulnerável à injeção de sql. Além disso, é difícil de ler e um pesadelo para manter (como você mostrou). Tente usar variáveis ​​bind sempre que possível. É uma codificação melhor e muito mais legível.

Exemplo:

DECLARE
  l_ename emp.ename%TYPE := 'KING';
  l_statement VARCHAR2(4000);
  l_result  VARCHAR2(4000);
BEGIN
   -- without bind variables
   l_statement := q'!
SELECT ename ||' earns '|| sal
  FROM emp where ename = !' || '''KING''';
    EXECUTE IMMEDIATE l_statement INTO l_result;
  dbms_output.put_line(l_result);

   -- with bind variables
   l_statement := q'!
SELECT ename ||' earns '|| sal
  FROM emp where ename = :1!';
    EXECUTE IMMEDIATE l_statement INTO l_result USING l_ename;
  dbms_output.put_line(l_result);
END;
/
KING earns 5000
KING earns 5000