Início / coding / Perguntas / 79334373
Accepted
Jonathan
Asked: 2025-01-07 05:24:14 +0800 CST

Substituir Indireto em uma fórmula Countifs no Planilhas Google

  • 772

Estou tentando descobrir uma maneira de substituir tudo isso indirectnesta fórmula:

={
"𝒇x"; 
MAP($A9:$A; LAMBDA(x; IF(AND(x <> ""; index(AL:AL; ROW(x)) <> "");
    IFERROR(
        (COUNTIFS(indirect("DY"&ROW(x)&":"&ROW(x)); "P"; $DY$6:$6; $AL$6; $DY$5:$5; "H") + 
         COUNTIFS(indirect("DY"&ROW(x)&":"&ROW(x)); "D"; $DY$6:$6; $AL$6; $DY$5:$5; "H")) / 
        (COUNTIFS(indirect("DY"&ROW(x)&":"&ROW(x)); "P"; $DY$6:$6; $AL$6; $DY$5:$5; "H") + 
         COUNTIFS(indirect("DY"&ROW(x)&":"&ROW(x)); "D"; $DY$6:$6; $AL$6; $DY$5:$5; "H") + 
         COUNTIFS(indirect("DY"&ROW(x)&":"&ROW(x)); "I"; $DY$6:$6; $AL$6; $DY$5:$5; "H") + 
         COUNTIFS(indirect("DY"&ROW(x)&":"&ROW(x)); "E"; $DY$6:$6; $AL$6; $DY$5:$5; "H") + 
         COUNTIFS(indirect("DY"&ROW(x)&":"&ROW(x)); "A"; $DY$6:$6; $AL$6; $DY$5:$5; "H"))
    ; "-")
; "")))}

Usei a seguinte fórmula até agora, mas ela para de funcionar assim que modifico a célula ou mesmo quando apenas copio/limpo e colo novamente a mesma fórmula na mesma célula (parece que isso index(DY:; ROW(x)) : index (DY:;ROW(x))não é mais suportado ou reconhecido como parte de uma fórmula).

={
"𝒇x"; 
MAP($A9:$A; LAMBDA(x; IF(AND(x <> ""; index(AL:AL; ROW(x)) <> "");
    IFERROR(
        (COUNTIFS(index(DY:; ROW(x)) : index(DY:;ROW(x)); "P"; $DY$6:$6; $AL$6; $DY$5:$5; "H") + 
         COUNTIFS(index(DY:; ROW(x)) : index(DY:;ROW(x)); "D"; $DY$6:$6; $AL$6; $DY$5:$5; "H")) / 
        (COUNTIFS(index(DY:; ROW(x)) : index(DY:;ROW(x)); "P"; $DY$6:$6; $AL$6; $DY$5:$5; "H") + 
         COUNTIFS(index(DY:; ROW(x)) : index(DY:;ROW(x)); "D"; $DY$6:$6; $AL$6; $DY$5:$5; "H") + 
         COUNTIFS(index(DY:; ROW(x)) : index(DY:;ROW(x)); "I"; $DY$6:$6; $AL$6; $DY$5:$5; "H") + 
         COUNTIFS(index(DY:; ROW(x)) : index(DY:;ROW(x)); "E"; $DY$6:$6; $AL$6; $DY$5:$5; "H") + 
         COUNTIFS(index(DY:; ROW(x)) : index(DY:;ROW(x)); "A"; $DY$6:$6; $AL$6; $DY$5:$5; "H"))
    ; "-")
; "")))}

Preciso substituir o indireto porque minha planilha tem muitos deles e isso deixa a planilha lenta (ou até mesmo impede que certas partes da minha planilha funcionem). Existe uma maneira de substituir o indireto ou apenas fazer o sistema reconhecer o código novamente?

google-sheets

1 respostas

  1. Best Answer

    Você pode tentar isso no lugar de indirect:

    offset(index(DY:DY;row(x));;;;columns(1:1))

    Alternativa:

    =vstack("𝒇x", 
    map(A5:A,lambda(x,if(and(x<>"",index(C:C,row(x))<>""),index(iferror(
        countifs(xmatch(index(D:D,row(x)):index(ZZZ:ZZZ,row(x)),{"P","D"})^0, 1, D2:2, C2, D1:1, "H") / 
        countifs(xmatch(index(D:D,row(x)):index(ZZZ:ZZZ,row(x)),{"P","D","I","E","A"})^0, 1, D2:2, C2, D1:1, "H") 
    , "-")),))))

    insira a descrição da imagem aqui

    • 2

relate perguntas