Início / coding / Perguntas / 79317281
Accepted
NanoTech
Asked: 2024-12-30 18:05:41 +0800 CST

Formatando data dentro do comando bash awk

  • 772

Estou tentando obter a data de alguns logs em um determinado formato para fazer algumas comparações posteriormente. Aqui está meu comando:

fgrep "<expression>" <logFile> | sort | awk -F "[][]" 'messageDate=$(date -d "$2" "+%Y.%j.%H.%M.%S") { print messageDate }'

O que me é impresso são as linhas completas dos arquivos de log.

Se em vez disso eu executar isto:

fgrep "<expression>" <logFiles> | sort | awk -F "[][]" 'messageDate=$(date -d "$2" "+%Y.%j.%H.%M.%S") { print $2 }'

Recebo as datas, mas não no formato que desejo.

2014-09-04T08:22:16Z
2017-10-08T16:05:06Z
2022-11-30T14:50:16Z

Os arquivos de log têm mensagens como esta:

[2022-11-30T14:50:16Z] <Info/Warning/Error>: <log message>

Alguém entende por que o awk está funcionando, ou seja, ele está dividindo o arquivo corretamente, mas o código messageDate=$(date -d "$2" "+%Y.%j.%H.%M.%S")está de alguma forma recebendo a mensagem de log completa novamente?

bash

2 respostas

  1. Best Answer

    Sobre o "comando bash awk" - bash e awk são 2 ferramentas completamente diferentes. Você pode chamar awk do bash, ou pode chamar bash do awk, assim como você pode chamar um programa C ou script perl do bash e vice-versa, mas cada ferramenta tem sua própria linguagem, escopo, etc.

    Quando você escreveu:

    awk -F "[][]" '
    messageDate=$(date -d "$2" "+%Y.%j.%H.%M.%S") {
        print messageDate
    }
'

    você está tentando usar a sintaxe bash dentro de um script awk, o que tem tantas chances de funcionar quanto tentar usar a sintaxe bash dentro de um programa C.

    Para chamar um utilitário Unix como datefrom awk(por meio de um shell intermediário como bash) e armazenar o resultado em uma variável awk e então imprimir o resultado se a operação for bem-sucedida, como você parece estar tentando fazer em seu script, seria isso usando qualquer awk:

    awk -F "[][]" '
    {
        messageDate = ""
        if ( ("date -d \047" $2 "\047 \047+%Y.%j.%H.%M.%S\047" | getline line) > 0 ) {
            messageDate = line
        }
    }
    messageDate != "" { print messageDate }
'

    Veja http://awk.freeshell.org/AllAboutGetline (ou, se estiver inativo, https://web.archive.org/web/20221109201352/http://awk.freeshell.org/AllAboutGetline ) para mais informações sobre como estou usando getlinelá.

    Se você estiver usando o GNU awk, ele tem suas próprias funções de tempo integradas , então você pode fazer:

    awk -F "[][]" '
    {
        messageDate = ""
        secs = mktime( gensub(/[-T:Z]/, " ", "g", $2), 1 )
        if ( secs >= 0 ) {
            messageDate = strftime("%Y.%j.%H.%M.%S", secs)
        }
    }
    messageDate != "" { print messageDate }
' file

    o que seria ordens de magnitude mais rápido do que ter o awk gerando um shell para chamar dateuma vez por linha de entrada.

    • 5

  2. Você pode tentar esta solução:

    awk -F '[][]' '/expression/ {print $2}' logFile | 
date "+%Y.%j.%H.%M.%S" -f - |
sort -n

    Observe que você não precisará grep, pois awkpode fazer esse trabalho também, imprimir somente essas colunas quando encontrar texto expressionem uma linha.

    • 4

relate perguntas