Como criar hard link no Racket?

Todo o sistema de arquivos no Racket tenta ser portátil entre sistemas Unixish e Windows, então não há suporte direto para criar links físicos (que não são suportados pelo Windows, até onde eu sei).

Aqui está um pequeno módulo que usa o FFI para chamar a chamada link(2)de sistema subjacente para criar um link físico que você pode usar:

#lang racket/base

(require ffi/unsafe ffi/unsafe/define (rename-in racket/contract [-> -->]))

(provide
 (contract-out
  [make-hard-link (--> path-string? path-string? boolean?)]))

(define-ffi-definer define-syscall (ffi-lib #f))
(define-syscall link (_fun #:save-errno 'posix _path _path -> _int))

(define (make-hard-link from to)
  (define ret (link (path->complete-path from) (path->complete-path to)))
  (cond
    [(= ret 0) #t] ; success
    [(= ret -1) ; error; raise an exception
     (define errno (saved-errno))
     (raise
      (make-exn:fail:filesystem:errno
       (format "make-hard-link: creating hard link failed;\n  from: ~A\n  to: ~A\n  errno: ~A" from to errno)
       (current-continuation-marks)
       (cons errno 'posix)))]
    [else ; shouldn't happen but catch just in case
     (error 'make-hard-link "invalid return value from link(2) syscall: ~A" ret)]))