Início / coding / Perguntas / 79297713
Accepted
NewUsr_stat
Asked: 2024-12-20 23:34:58 +0800 CST

Substituir valores em um conjunto de dados por valores em outro conjunto de dados, mas somente quando uma variável assume um valor específico

  • 772

suponha que tenha o seguinte conjunto de dados:

data have;
  input ID :$20. Admission :date09. Discharge :date09. Index Variable1 Variable2; 
  format Admission date9. Discharge date9.;
cards;
0001 13JAN2015 20JAN2015 1  2  4  
0001 21FEB2015 31DEC2015 0  .  2
0001 21FEB2015 31DEC2015 0  3  .
0001 01JAN2019 31DEC2019 0  6  9
0002 01JAN2015 31DEC2015 0  2  .
0002 01JAN2019 31OCT2019 1  .  2
0002 01JAN2019 31OCT2019 0  .  2
;

Então, tenho outro conjunto de dados que se parece com este e vem de outro cálculo:


data have1;
  input ID :$20. Admission :date09. Discharge :date09. Index Variable1 Variable2; 
  format Admission date9. Discharge date9.;
cards;
0001 13JAN2015 20JAN2015 1  6  8
0002 01JAN2019 31OCT2019 1  4  2
;

Existe uma maneira de obter o seguinte?

data have2;
  input ID :$20. Admission :date09. Discharge :date09. Index Variable1 Variable2; 
  format Admission date9. Discharge date9.;
cards;
0001 13JAN2015 20JAN2015 1  6  8 
0001 21FEB2015 31DEC2015 0  .  .
0001 21FEB2015 31DEC2015 0  .  .
0001 01JAN2019 31DEC2019 0  .  .
0002 01JAN2015 31DEC2015 0  .  .
0002 01JAN2019 31OCT2019 1  4  2
0002 01JAN2019 31OCT2019 0  .  .
;

Em outras palavras, eu gostaria de substituir valores em have por valores em have1 (onde Index = 1). O restante em have deve ser definido como "." para ter have3. O número total de variáveis: é 50. Aqui, apenas 2 são mostrados para simplificar.

Agradeço antecipadamente

sas

1 respostas

  1. Best Answer

    Você pode fazer isso de duas maneiras:

    1. Uma fusão simples
    2. Uma junção hash

    Vamos dar uma olhada em ambos.

    Mesclagem Simples

    Queremos mesclar pela chave, que é a combinação de ID Admission Discharge Index. Primeiro, classificaremos ambos os conjuntos de dados e, em seguida, os mesclaremos por essa chave. Se a combinação de chaves corresponder, definiremos Variable1e Variable2como ausente.

    proc sort data=have;
    by id admission discharge index;
run;

proc sort data=have1;
    by id admission discharge index;
run;

data want;
    merge have(in=h)
          have1(in=h1)
    ;
    by id admission discharge index;

    if(h NE h1) then call missing(of variable:);
run;

    Junção de Hash

    Isso é muito parecido com uma mesclagem simples, mas não requer classificação e tem o melhor desempenho. Trataremos have1como uma tabela de consulta e extrairemos valores dela para cada correspondência. Se não encontrarmos uma correspondência, definiremos os valores de Variable1e Variable2como missing.

    data want;
    set have;

    if(_N_ = 1) then do;
        dcl hash h1(dataset:'have1');
            h1.defineKey('id', 'admission', 'discharge', 'index');
            h1.defineData('variable1', 'variable2');
        h1.defineDone();
    end;

    if(h1.Find() NE 0) then call missing(of variable:);
run;

    ID      Admission   Discharge   Index   Variable1   Variable2
0001    13JAN2015   20JAN2015   1       6           8
0001    21FEB2015   31DEC2015   0       .           .
0001    21FEB2015   31DEC2015   0       .           .
0001    01JAN2019   31DEC2019   0       .           .
0002    01JAN2015   31DEC2015   0       .           .
0002    01JAN2019   31OCT2019   1       4           2
0002    01JAN2019   31OCT2019   0       .           .
    • 1

relate perguntas