Início / coding / Perguntas / 79283678
Accepted
Charles Kenyon
Asked: 2024-12-16 12:51:05 +0800 CST

Problema ao percorrer os estilos para alterar NextParagraphStyle - Erro de tempo de execução 91 - Word vba

  • 772

Problema ao percorrer os estilos para alterar NextParagraphStyle - Erro de tempo de execução 91 - Word vba

EDIT: Tim Williams percebeu o problema. Eu não estava usando Set para uma variável de objeto.

Minha macro é:

Sub StyleFollowingBodyText()
    ' Charles Kenyon 15 December 2024
    ' Set the following style for most QuickStyle paragraph styles to be Body Text
    Dim StyleCount As Long
    Dim thisStyle As Style
    Dim iCount As Long
    '
    With ActiveDocument
        Let StyleCount = .Styles.Count
        For iCount = 1 To StyleCount
            Let thisStyle = .Styles(iCount)
            If thisStyle.QuickStyle = True Then
                If thisStyle.Type = wdStyleTypeParagraph Or wdStyleTypeLinked Then
                    If thisStyle.NameLocal <> "Normal" Then
                        thisStyle.NextParagraphStyle = "Body Text"
                    End If
                End If
            End If
        Next iCount
    End With
End Sub

e recebo esta mensagem de erro ao executá-lo:

captura de tela do erro 91

Esta mensagem de erro parece ser um pouco "pega-tudo" e não é muito útil. Conforme apontado por Tim Williams, o problema não é usar o comando Set para uma variável de objeto.

Está parando em Let thisStyle = .Styles(iCount).

O propósito da macro é alterar a maioria dos QuickStyles de parágrafo para ter o estilo Body Text como o estilo a seguir. Estou tentando alterar mais de 50 [Quick] Style Sets porque prefiro não ter a maior parte dos meus documentos usando o estilo Normal.

vba

2 respostas

  1. Best Answer

    Por exemplo:

    Sub StyleFollowingBodyText()
Dim s As Long
With ActiveDocument
  For s = 1 To .Styles.Count
    With .Styles(s)
      If .QuickStyle = True Then
        If .NameLocal <> "Normal" Then
          If .Type = wdStyleTypeParagraph Or .Type = wdStyleTypeParagraph Then .NextParagraphStyle = "Body Text"
        End If
      End If
    End With
  Next
End With
End Sub
    • 1

  2. Tentei descartar a declaração do problema e não atribuir uma variável ao estilo e funcionou.

    Eu simplesmente usei .Styles(iCount) em vez da variável StyleCount.

    Sub StyleFollowingBodyText2()
    ' Charles Kenyon 15 December 2024
    ' Set the following style for most QuickStyle paragraph styles to be Body Text
    Dim StyleCount As Long
    Dim thisStyle As Style
    Dim iCount As Long
    '
    With ActiveDocument
        Let StyleCount = .Styles.Count
        For iCount = 1 To StyleCount
'            Let thisStyle = .Styles(iCount)
            If .Styles(iCount).QuickStyle = True Then
                If .Styles(iCount).Type = wdStyleTypeParagraph Or wdStyleTypeLinked Then
                    If .Styles(iCount).NameLocal <> "Normal" Then
                        .Styles(iCount).NextParagraphStyle = "Body Text"
                    End If
                End If
            End If
        Next iCount
    End With
End Sub

    O comentário de Tim Williams à minha pergunta é certeiro quanto ao motivo pelo qual eu estava recebendo o erro. Eu estava usando "Let" em vez de "Set" para uma variável de objeto.

    Também encontrei a seguinte macro de Jay Freedman lidando com os estilos do modelo Normal.

    Sub StylesToBodyText()
    ' Jay Freedman 2023-12-18
    ' Change next style to Body Text, Based on style to Body Text in Normal
    ' You can use the macro below to change all of the "based on Normal" and "following paragraph Normal" styles
    '    in the Normal.dotm template to be based on and followed by Body Text.
    ' Before you run the macro, save a copy of the Normal.dotm template in some folder other
    '    than the Templates folder, as a backup in case something goes wrong.
    ' I deliberately did not include a Save in the macro,
    '    as you should examine the results in the Styles pane before you manually save and close the Normal.dotm window.
    '    If anything is amiss, close the window without saving and see where the problem occurred.
    ' https://answers.microsoft.com/en-us/msoffice/forum/all/how-to-change-the-style-for-following-paragraph/64644dfc-92a7-44b7-baa8-53fe622344b8
    '
    Dim sty As Style
    NormalTemplate.OpenAsDocument ' Comment this line out to apply active document or template and not normal template
    For Each sty In ActiveDocument.Styles
        If sty.Type = wdStyleTypeParagraph Then
            If sty.BaseStyle = "Normal" Then
                sty.BaseStyle = "Body Text"
            End If
'
            If sty.NextParagraphStyle = "Normal" Then
                sty.NextParagraphStyle = "Body Text"
            End If
        End If
    Next sty
    '   After checking styles, save and close normal template
End Sub

    Provavelmente adotarei essa estrutura, mas pensei que poderia ajudar outros aqui também. Ele está usando a estrutura For...Each em vez da count.

    • 0

relate perguntas