Início / coding / Perguntas / 79262686
Accepted
Shawn Zhang
Asked: 2024-12-08 22:46:08 +0800 CST

Como converter Map.adjust para monádico?

  • 772

No código funciona bem como abaixo

divide :: Int -> Int -> Either String Int
divide a 0 = Left "Error with 0"
divide a b = Right (a `div` b)

O código a ser alterado

Map.adjust (divide 3) "A" $ Map.fromList [("A",3),("B",0)]

O resultado esperado deve ser:

Map.adjust (divide 3) "A" $ Map.fromList [("A",3),("B",0)] 
=>  Right $ Map.fromList [("A",1),("B",0)]   

Map.adjust (divide 3) "B" $ Map.fromList [("A",3),("B",0)]
=>  Left "Error with 0"

Ou em geral como construir uma função como:

Map.adjust:: (a -> m a) -> k -> (Map k a) -> m (Map k a)

Muito obrigado !

dictionary

2 respostas

  1. Best Answer

    Uma função adjustMcom tipo (a -> m a) -> k -> (Map k a) -> m (Map k a)pode ser definida sobre a função já existente alterF :: (Functor f, Ord k) => (Maybe a -> f (Maybe a)) -> k -> Map k a -> f (Map k a).

    alterFé mais geral porque, além de permitir efeitos, também permite remover o valor alvo ou inseri-lo quando a chave ainda não existe. (É para isso que Maybeservem os s na assinatura).

    adjustM :: (Ord k, Applicative m) => (a -> m a) -> k -> Map k a -> m (Map k a)
adjustM f = Map.alterF (\ma -> case ma of
   -- No value? We do nothing.
   Nothing -> pure Nothing
   -- There's a value? We transform it.
   Just v -> Just <$> f v)

    Ou, mais sucintamente,

    adjustM :: (Ord k, Applicative m) => (a -> m a) -> k -> Map k a -> m (Map k a)
adjustM f = Map.alterF (traverse f)
    • 9

  2. Podemos implementar isso usando insert:

    updateM :: (Ord k, Applicative m) => (a -> m a) -> k -> Map k a -> m (Map k a)
updateM f k map = case (map !? k) of
  Just v -> flip (insert k) map <$> f v
  _ -> pure map

    Portanto, primeiro verificamos se a chave existe, se existir, executamos f ve então usamos isso para inserir o novo valor no map.

    Isso gera o resultado esperado:

    ghci> updateM (divide 3) "A" $ Data.Map.fromList [("A",3),("B",0)]
Right (fromList [("A",1),("B",0)])
ghci> updateM (divide 3) "B" $ Data.Map.fromList [("A",3),("B",0)]
Left "Error with 0"
    • 2

relate perguntas