Converter XML para JSON com atributos e texto como chaves sem __text

O recurso integrado não permite a personalização da saída. Para atingir a saída esperada, você precisa de uma transformação personalizada. Ela pode ser implementada criando uma função recursiva que, quando recebe um objeto com atributos, produz um objeto com o valor atual sob uma nova chave com o mesmo nome da chave existente e concatena os atributos como novos valores-chave. Caso contrário, retorna o valor aplicando recursivamente a mesma transformação. Qualquer outro tipo está retornando como está. Minha implementação inclui mapear cada elemento de uma matriz, embora não haja matrizes em entradas XML. Deve funcionar com outro formato, mas não testei.

Exemplo

Função:

%dw 2.0
output application/json 
fun writeWithAttributes(x) = x match {
    case o is Object -> 
        o mapObject ((value, key, index) ->
            if (isEmpty(key.@)) // if there are no attributes just return the same key and transform the value
                { (key): writeWithAttributes(value) } 
            else // if there are attributes add a new child object with the keys collected and the value repeating the same key.
                {
                    (key): { 
                        (key): writeWithAttributes(value), 
                        (key.@ mapObject ("@"++$$ as String): $) 
                    }
                } 
        )

    case a is Array -> a map writeWithAttributes($)
    else -> x
  }
---
writeWithAttributes(payload) 

Entrada:

<CustomData>
  <CustomIdentifier attribute1="value1" attribute2="value2">test</CustomIdentifier>
</CustomData>

Saída:

{
  "CustomData": {
    "CustomIdentifier": {
      "CustomIdentifier": "test",
      "@attribute1": "value1",
      "@attribute2": "value2"
    }
  }
}