Início / coding / Perguntas / 79239759
Accepted
Ramadan Moussa
Asked: 2024-11-30 22:34:10 +0800 CST

Copiando entre duas pastas de trabalho diferentes com VBA

  • 772

Recebi um código para copiar dados de uma pasta de trabalho fechada para outra pasta de trabalho ativa, mas tenho um problema ao fechar as pastas de trabalho após executar o código. Não sei como consertar.

minha pasta de trabalho de origem é "Parar trabalho" planilha1 e a pasta de trabalho de destino é "AUTHS" e o nome da planilha é "parar trabalho" o código roda sem problemas, mas meu problema é que depois de executar o código e copiar os dados minha pasta de trabalho ativa na qual estou trabalhando "AUTHS" é fechada e a pasta de trabalho de origem que foi fechada é aberta enquanto eu preciso do vice-versa (para salvar e fechar "parar trabalho" e manter "AUTHS" aberto - Eu tentei alterar verdadeiro e falso, mas nada aconteceu este é meu código

Sub mycode()

Workbooks.Open Filename:="D:\Desktop\Stop Work.xlsm"
Worksheets("Sheet1").Cells.Select
Selection.Copy

Workbooks.Open Filename:="D:\Desktop\AUTHs.xlsm"
Worksheets("Stop Work").Cells.Select
Selection.PasteSpecial xlPasteAll             'xlPasteAll to paste everything
ActiveWorkbook.Save

ThisWorkbook.Close SaveChanges:=False        'to close the file
Workbooks("D:\Desktop\Stop Work.xlsm").Close SaveChanges:=True  'to close the file

End Sub



thank you in advance
excel

2 respostas

  1. Best Answer

    Melhor usar variáveis ​​para identificar as pastas de trabalho. Algo como abaixo

    ' Open the source workbook  
Set sourceWorkbook = Workbooks.Open(Filename:="D:\Desktop\Stop Work.xlsm")  

sourceWorkbook.Worksheets("Sheet1").Cells.Copy  

' Open the destination workbook  
Set destinationWorkbook = Workbooks.Open(Filename:="D:\Desktop\AUTHs.xlsm")  
 
destinationWorkbook.Worksheets("Stop Work").Cells.PasteSpecial xlPasteAll  

destinationWorkbook.Save  

' Close the source workbook after saving changes  
sourceWorkbook.Close SaveChanges:=False
    • 0

  2. Copiar da pasta de trabalho fechada

    Sub CopyFromClosedWorkbook()
    
    ' Reference the source objects.
    Dim swb As Workbook: Set swb = Workbooks.Open("D:\Desktop\Stop Work.xlsm")
    Dim sws As Worksheet: Set sws = swb.Sheets("Sheet1")
    Dim srg As Range:
    With sws.UsedRange
        Set srg = sws.Range("A1", .Cells(.Cells.CountLarge))
    End With
    
    ' Reference the destination objects.
    Dim dwb As Workbook: Set dwb = ThisWorkbook ' workbook containing this code
    Dim dws As Worksheet: Set dws = dwb.Sheets("Stop Work")
    Dim dfcell As Range
    ' Either overwrite...
    dws.UsedRange.Clear ' clear existing data
    Set dfcell = dws.Range("A1")
    ' ... or append:
    'With dws.UsedRange
    '    Set dfcell = .Cells(1).EntireRow.Columns("A").Offset(.Rows.Count)
    'End With
    Dim drg As Range: Set drg = dfcell.Resize(srg.Rows.Count, srg.Columns.Count)
    
    ' Either copy values, formulas and formatting...
    srg.Copy Destination:=drg
    ' ... or copy only values:
    'drg.Value = srg.Value
    
    ' Close the source workbook.
    swb.Close SaveChanges:=False ' just read from
    
    ' Save the destination workbook.
    dwb.Save
    
    ' Inform.
    MsgBox "Data copied.", vbInformation

End Sub
    • 0

relate perguntas