Início / coding / Perguntas / 79203037
Accepted
issamo
Asked: 2024-11-19 18:31:20 +0800 CST

Existe uma maneira de criar uma fórmula no Catia via Macro para vincular parâmetros?

  • 772

insira a descrição da imagem aquio objetivo principal é vincular dois parâmetros via fórmula no Catia usando macro. Tentei registrar o processo manualmente, mas o código não deu o código completo:

Sub CATMain()
Dim partDocument1 As partDocument
Set partDocument1 = CATIA.ActiveDocument
Dim part1 As part
Set part1 = partDocument1.part
Dim parameters1 As Parameters
Set parameters1 = part1.Parameters
Dim parameterSet1 As ParameterSet
Set parameterSet1 = parameters1.RootParameterSet
Dim parameterSets1 As ParameterSets
Set parameterSets1 = parameterSet1.ParameterSets
Dim parameterSet2 As ParameterSet
Set parameterSet2 = parameterSets1.GetItem("Construction_Position")
Dim parameterSets2 As ParameterSets
Set parameterSets2 = parameterSet2.ParameterSets
Dim parameterSet3 As ParameterSet
Set parameterSet3 = parameterSets2.GetItem("R_Point") ' Cannot print the method call put_Value for the object RealParam
Dim relations1 As Relations
Set relations1 = part1.Relations
Set parameterSet3 = parameterSets2.GetItem("R_Point")
Dim formula1 As Formula
Set formula1 = relations1.CreateFormula("Formula.2", "", ' Cannot print the method call CreateFormula for the object Relations
part1.Update
End Sub

a fórmula final que obtenho deste processo 'manualmente' é

formula.2: Construction_Position\R_Point\R_Point_X=Construction_Position\H_Point\H_Point_X

alguém pode me ajudar por favor com isso. Eu tentei com CHATGPT mas não está funcionando de jeito nenhum

vba

2 respostas

  1. Não sou especialista em Catia, mas li rapidamente http://catiadoc.free.fr/online/interfaces/interface_Relations.htm#CreateFormula e tente o seguinte:

    Sub CATMain()
    Dim partDocument1 As PartDocument
    Dim part1 As Part
    Dim relations1 As Relations
    Dim formula1 As Formula
    Dim parameters1 As Parameters
    Dim paramHPointX As Parameter
    Dim paramRPointX As Parameter

    Set partDocument1 = CATIA.ActiveDocument
    Set part1 = partDocument1.Part
    Set parameters1 = part1.Parameters
    Set relations1 = part1.Relations
    Set paramHPointX = parameters1.Item("Construction_Position\H_Point\H_Point_X")
    Set paramRPointX = parameters1.Item("Construction_Position\R_Point\R_Point_X")

    'formula linkin
    ' Formula syntax: "iName", "iComment", "Formula"
    Set formula1 = relations1.CreateFormula("Formula.4", "", paramRPointX.Name & " = " & paramHPointX.Name)
    part1.Update
End Sub
    • 0
  2. Best Answer

    CreateFormulaprecisa como terceira entrada o parâmetro que é gerenciado pela fórmula, e como quarto parâmetro a fórmula como uma string. a melhor maneira de obter o "nome" de um parâmetro para usar em uma fórmula é usar a GetNameToUseInRelationfunção. Além disso, seu código não acessa um nível de conjunto de parâmetros. Aqui está um exemplo de como esse código poderia se parecer

    Sub CATMain()

Dim oPart As Part
Dim oRelations As Relations
Dim oParameters As Parameters
Dim parameterSet_H As ParameterSet
Dim parameterSet_R As ParameterSet
Dim parameterSet_Construction As ParameterSet
Dim oParameter_H as Parameter
Dim oParameter_R as Parameter
Dim oFormula As Formula

Set oPart = CATIA.ActiveDocument.Part
Set oRelations = oPart.Relations
Set oParameters = oPart.Parameters

'get Parametersets
Set parameterSet_Construction = oParameters.RootParameterSet.ParameterSets.Item("Construction_Position")
Set parameterSet_H = parameterSet_Construction.ParameterSets.Item("H_Point")
Set parameterSet_R = parameterSet_Construction.ParameterSets.Item("R_Point")

'get Parameters
Set oParameter_H = parameterSet_H.DirectParameters.Item("H_Point_X")
Set oParameter_R = parameterSet_R.DirectParameters.Item("R_Point_X")

'create formula
Set oFormula = oRelations.CreateFormula("","", oParameter_R, oParameters.GetNameToUseInRelation(oParameter_H))

oPart.Update

End Sub
    • 0

relate perguntas