Início / coding / Perguntas / 79183067
Accepted
Kram Kramer
Asked: 2024-11-13 08:07:41 +0800 CST

A fórmula RANK fornece resultados incorretos quando existem mais de um valor

  • 772

1) Copie os seguintes valores e cole nas células A1:C8 da planilha do Excel.

Cabeçalho da coluna A Cabeçalho da coluna B Cabeçalho da coluna C
600 4 =CLASSIFICAÇÃO(A2,$A$2:$A$8,0)
1200 2 =CLASSIFICAÇÃO(A3,$A$2:$A$8,0)
500 5 =CLASSIFICAÇÃO(A4;$A$2:$A$8;0)
900 3 =CLASSIFICAÇÃO(A5;$A$2:$A$8;0)
500 5 =CLASSIFICAÇÃO(A6;$A$2:$A$8;0)
1300 1 =CLASSIFICAÇÃO(A7,$A$2:$A$8,0)
300 6 =CLASSIFICAÇÃO(A8;$A$2:$A$8;0)

2) A imagem a seguir mostra que a fórmula Rank fornece resultados incorretos

Esta imagem mostra que a fórmula RANK dá resultado errado.

3) A fórmula RANK dá resultado errado porque 500 existe na coluna A duas vezes.

4) Você conhece uma fórmula alternativa à fórmula RANK ?

5) Atualização: A solução desejada foi encontrada graças a Mayukh Bhattacharya, como segue.

SUMPRODUCT((A2<=$A$2:$A$8)/COUNTIF($A$2:$A$8;$A$2:$A$8))
excel

1 respostas

  1. Best Answer

    A fórmula que pode ajudar é:

    [B2]=LET(src,A2:A8,u,UNIQUE(src),XLOOKUP(src,SORT(u,,-1),SEQUENCE(ROWS(u))))

    insira a descrição da imagem aqui

    UNIQUE deixa apenas vendas únicas para permitir que as mesmas vendas ocupem um único lugar.

    SORT classifica as vendas exclusivas em ordem decrescente.

    Para cada venda (origem), o XLOOKUP a encontra nas vendas exclusivas classificadas para obter o lugar correspondente da sequência de lugares (1 a 6).

    LET suporta a definição de variáveis ​​temporárias como 'src' e 'u' para uso repetitivo.

    Fórmulas mais curtas!

    [B2]=LET(src,A2:A8,XMATCH(src,SORT(UNIQUE(src),,-1)))

    Nesta fórmula, XMATCH fornece o número do local sem geração de SEQUÊNCIA.

    O mesmo sem LET:

    =XMATCH(A2:A8,SORT(UNIQUE(A2:A8),,-1))

    Mais uma fórmula que conta o número de valores únicos superiores ao valor esquerdo para cada célula de B2:B8:

    =SUM(--(UNIQUE($A$2:$A$8)>=A2))

    Insira esta fórmula em B2 e preencha até B8.

    Créditos para @MayukhBhattacharya que encontrou a fórmula para versões anteriores do Excel. Com uma pequena modificação:

    [B2]=SUM((A2<=$A$2:$A$8)/COUNTIF($A$2:$A$8;$A$2:$A$8))

    Insira esta fórmula em B2 e preencha até B8.

    • 5

relate perguntas