Início / coding / Perguntas / 79161110
Accepted
Gabriel Aguilera
Asked: 2024-11-06 09:17:47 +0800 CST

Excel - como corrigir esta fórmula countif

  • 772

Tenho um problema com a fórmula COUNTIF que estou usando. Preciso encontrar um texto específico na Linha C com o valor da Linha A.

Preciso descobrir se alguma das células na linha C contém o valor da célula A2, que é p1234, no entanto, ele retorna "sim" mesmo com o valor de p12345678.

insira a descrição da imagem aqui

Tentei remover o curinga, mas também não funciona. insira a descrição da imagem aqui

Cola ColB ColC
p1234 NÃO Lorem ipsum dolor sit amet, consectetur adipiscing elit p123456789
p5478 SIM Lorem ipsum dolor sit amet, consectetur adipiscing elit p5478
p05384 SIM Lorem ipsum dolor sit amet, consectetur adipiscing elit p05384
excel

1 respostas

  1. Best Answer

    Tente usar a seguinte fórmula com SEARCH()função para obter a saída desejada:

    insira a descrição da imagem aqui

    =IF(SUM(1-ISERR(SEARCH(" "&A2&" "," "&C$2:C$4&" "))),"YES","NO")

    Se as chaves de pesquisa diferenciarem maiúsculas de minúsculas, elas podem ser usadas FIND()no lugar deSEARCH()

    =IF(SUM(1-ISERR(FIND(" "&A2&" "," "&C$2:C$4&" "))),"YES","NO")

    • Usando com ISNUMBER()+FIND()

    =IF(SUM(N(ISNUMBER(FIND(" "&A2&" "," "&C$2:C$4&" ")))),"YES","NO")

    • Ou,

    =IF(SUM(N(ISNUMBER(SEARCH(" "&A2&" "," "&C$2:C$4&" ")))),"YES","NO")

    Ou, usandoBYROW()

    =BYROW(A2:A4,LAMBDA(x,IF(OR(1-ISERR(FIND(" "&x&" "," "&C2:C4&" "))),"YES","NO")))

    • Outra maneira de fazer isso é usar TEXTAFTER()desde que a chave de pesquisa esteja sempre no final das strings a serem pesquisadas:

    =IF(OR(1-ISNA(TEXTAFTER(" "&C2:C4&" "," "&A2&" "))),"Yes","No")
    • 0

relate perguntas