Início / coding / Perguntas / 79157339
Accepted
Forward Ed
Asked: 2024-11-05 08:12:05 +0800 CST

Como obter o número da linha da tabela em vez do número da linha da planilha

  • 772

Acabei de fazer uma pergunta sobre como obter o número da coluna para um nome de coluna conhecido e a resposta foi.index

Estou tentando retornar a última linha usada para uma tabela nomeada inteira. Se eu usasse o método .end(xlup) com base na planilha, ele sempre pararia na borda da tabela, independentemente de a célula inferior da tabela estar vazia ou não. Em vez disso, alterei para o seguinte:

Meu código:

Function TableLastUsedRow(TheTable As ListObject) As Long

Dim RowCount As Long, ColCount As Long, TableLastRow As Long

    With TheTable
        TableLastRow = .ListRows.count
    
        For ColCount = 1 To .ListColumns.count
            If IsEmpty(.DataBodyRange.Cells(TableLastRow, ColCount)) Then
                RowCount = .DataBodyRange.Cells(TableLastRow, ColCount).End(xlUp).Row
                If TableLastUsedRow < RowCount Then TableLastUsedRow = RowCount
            Else
                TableLastUsedRow = TableLastRow
                Exit Function
            End If
        Next ColCount
    End With

End Function

Isso funciona muito bem para retornar a referência de linha da planilha. Como você obtém o número da linha da tabela?

Linha de código atualizada

RowCount = .DataBodyRange.Cells(TableLastRow, ColCount).End(xlUp).ListRow.Index

Isso está gerando o seguinte erro:

insira a descrição da imagem aqui

excel

2 respostas

  1. Best Answer

    Índice da última linha não vazia (dados) de uma tabela do Excel

    Function TableLastUsedRow(ByVal TheTable As ListObject) As Long
    With TheTable
        Dim RowsCount As Long: RowsCount = .ListRows.Count
        ' The following line will exit the function and return 0.
        ' It might be better to return -1. You know how.
        If RowsCount = 0 Then Exit Function ' empty table
        With .DataBodyRange
            Dim lcell As Range:
            Set lcell = .Find("*", , xlValues, , xlByRows, xlPrevious)
            If lcell Is Nothing Then Exit Function ' all cells are blank
            ' Number of Populated (Data) Rows =
            '     Last Worksheet Row - First Worksheet Row + 1
            TableLastUsedRow = lcell.Row - .Row + 1
        End With
    End With
End Function
    • 2

  2. Abordagem diferente - basta fazer um loop para trás sobre as linhas

    Sub Tester()
    Debug.Print LastUsedRowIndex(ActiveSheet.ListObjects(1))
End Sub


'Return the index of the last row in the table `TheTable`
' return zero if table is empty
Function LastUsedRowIndex(TheTable As ListObject) As Long
    Dim i As Long
    For i = TheTable.ListRows.Count To 1 Step -1
        If Application.CountA(TheTable.ListRows(i).Range) > 0 Then Exit For
    Next i
    LastUsedRowIndex = i
End Function
    • 2

relate perguntas