Converter aaaamm em sas date9 e dividir

Se você tiver uma variável de caractere, você pode usar o YYMMN informat para convertê-lo em um valor de data. Você pode então usar o formato MONYY para exibi-lo como JUL2024.

875   data test;
876    x=input('202407',yymmn6.);
877    put x=comma. x=date9. x=monyy7.;
878   run;

x=23,558 x=01JUL2024 x=JUL2024

Você também pode usar as funções MONTH() e YEAR() para calcular o número do ano e o número do mês.

Então, se o seu conjunto de dados existente for chamado HAVE e a variável existente for chamada DATE_CHAR, você poderá usar um código como este para criar uma nova variável chamada DATE_NUM.

 data want;
    set have;
    date_num = input(date_char,yymmn6.);
    year = year(date_num);
    month = month(date_num);
    format date_num monyy7. month z2. ;
 run;

Se você quiser o ANO e o MÊS como strings, você pode simplesmente usar a função SUBSTR() para separar sua variável de caractere.

 data want;
   set have;
   year_char = substr(date_char,1,4);
   month_char = substr(date_char,5,2);
 run;

Se a variável existente já for uma variável com valor DATE, mas tiver o formato YYMMN6. anexado a ela para que ela imprima no estilo aaaamm, então você pode pular a função INPUT(), pois você já tem um valor de data. Você pode apenas alterar o formato anexado para que ele imprima no estilo MONYYYY em vez do estilo YYYYMM.

 data want;
    set have;
    year = year(date_num);
    month = month(date_num);
    format date_num monyy7. month z2. ;
 run;

Se a variável existente for apenas um número regular com valores como YYY,YMM (onde as casas das unidades e dezenas representam o número do mês), então primeiro converta-a para uma string de 6 dígitos usando a função PUT() com o formato 6. ou Z6. Então aplique a lógica acima para converter a string de 6 dígitos de volta para um valor de dados.

data want;
   set have;
   date_char = put(date_num,Z6.);
   date_num = input(date_char,yymmn6.);
   year = year(date_num);
   month = month(date_num);
   format date_num monyy7.;
run;

Ou você pode usar aritmética para obter o ano e o mês do número. Então use o ano e o mês numéricos para gerar um valor de data real.

data want;
   set have;
   year = int(date_num/100);
   month = mod(date_num,100);
   date_num = mdy(month,1,year);
   format date_num monyy7. month z2. ;
run;