Início / coding / Perguntas / 79108504
Accepted
Chris
Asked: 2024-10-21 11:50:37 +0800 CST

Como posso usar índice e correspondência de pesquisa bidirecional

  • 772

Preciso de uma fórmula que adicione o nome das enfermeiras da coluna F na coluna D se elas tiverem aquela sala (G3 a K7)

Por exemplo: a enfermeira A atualmente tem os quartos 2101, 2108, 2155, 2165, então seu nome deve ser exibido na linha específica do quarto.

Sala Nome/Idade do Paciente Código Enfermeira
2101 Completo
2102 Completo
2103 Completo
2104 FC
2105
2106 Completo
2107
2108 Completo
2109 Completo
2110 Completo
2151 Completo
2152
2153 Completo
2154 Completo
2155 FC
2156 Completo
2157 Completo
2161 Completo
2162 Completo
2163
2164
Enfermeira Sala 1 Sala 2 Sala 3 Sala 4 Sala 5
UM 2101 2108 2155 2165
B 2102 2109 2156 2166
C 2103 2110 2157 2167
E 2104 2151 2161 2168
E 2105 2152 2162 2169
F 2106 2153 2163 2170
G 2107 2154 2164 2170

Imagem da folha

Usei o seguinte =IF(A3=H3,F3,"")e funcionou, mas só para uma célula. Tentei várias células e acabei quebrando a planilha.

excel

1 respostas

  1. Best Answer

    Tente usar qualquer uma das seguintes fórmulas de acordo com suas preferências:

    insira a descrição da imagem aqui

    • Usando IFS()+TOCOL()

    =TOCOL(IFS(A3=G$3:K$9,F$3:F$9),2)

    • Ou, usando REPT()+CONCAT()

    =CONCAT(REPT(F$3:F$9,G$3:K$9=A3))

    • Usando MAP()+ TOCOL()+ IFS()para retornar todo o intervalo como uma saída de matriz.

    =MAP(A3:A23,LAMBDA(x,TOCOL(IFS(G3:K9=x,F3:F9),2)))

    • Ou versões mais antigas -- usando INDEX()+ AGGREGATE()+ IFERROR():

    =IFERROR(INDEX(F$3:F$9,AGGREGATE(15,7,(ROW(F$3:F$9)-ROW(F$3)+1)/(G$3:K$9=A3),1)),"")

    • Ou, ETA LAMBDA()usando FILTER()+ BYROW()+OR()

    =FILTER(F$3:F$9,BYROW(G$3:K$9=A3,OR),"")

    • Ou, usando MAP()+ ETA LAMBDA()--> BYROW()+ FILTER()+OR()

    =MAP(A3:A23,LAMBDA(x,FILTER(F3:F9,BYROW(G3:K9=x,OR),"")))

    • Ou usando MMULT()+FILTER()

    =FILTER(F$3:F$9,MMULT(N(G$3:K$9=A3),TOCOL(--RIGHT(G$2:K$2))^0),"")

    Compartilho as maneiras possíveis, já que é possível retornar a saída de muitas maneiras. As soluções descritas acima dão uma ideia sobre o conceito de matrizes e também ajudam no aprendizado.

    • 1

relate perguntas