Início / coding / Perguntas / 79108288
Accepted
Pink Ninja
Asked: 2024-10-21 08:31:43 +0800 CST

Como trocar entidades de configuração dentro de arquivos de configuração?

  • 772

Peço desculpas se a pergunta já foi feita antes, realmente fiquei preso nessa questão por algumas horas, o que parece relativamente fácil. Consegui identificar dois padrões por meio do awk no arquivo único.

awk '/\[code\.change\..*\]/ {found=1; print; next} found && NF {print} found && !NF {exit}' filename
awk '/\[code\.test\..*\]/ {found=1; print; next} found && NF {print} found && !NF {exit}' filename

Existe a possibilidade de combinar esses dois awks em um para trocar os blocos?

um exemplo do arquivo de configuração está abaixo file.cfg

[code.change.1]
file.path=filename
file.contact=manager
file.active=TRUE

[code.test.1]
ls -la filepath
pwd
find . -name filename

Só precisa trocar a ordem da configuração. Obrigado

shell

3 respostas

  1. Best Answer

    Com o exemplo fornecido, você poderia tentar:

    awk -v RS= '                                                            # records are reparated by blank lines
    /^\[code\.change/ {pos1 = NR}                                       # position of the 1st block
    /^\[code\.test/ {pos2 = NR}                                         # position of the 2nd block
    {
        ary[NR] = $0                                                    # store the record in an array
    }
    END {
        tmp = ary[pos1]; ary[pos1] = ary[pos2]; ary[pos2] = tmp         # swap the two records
        for (i = 1; i <= NR; i++) print(ary[i], i<NR ? ORS : "")        # print the array
    }
' file.cfg
    • 5

  2. Se edestiver disponível/aceitável, algo como:

    #!/bin/sh

ed -s file.cfg <<'EOF'
  /^$/m$                                                ##: Move the blank/empty line at the end
  /^\[code\.change\.1\]/;/^\[code\.test\.1\]/-1m$       ##: From [code.change.1] down to [code.test.1] minus 1 line move to the end
  ,p                                                    ##: Print the changes from the buffer only, Does not edit the file.
  Q                                                     ##: Exit/quit silently
EOF

    Em uma linha

    printf '%s\n' '/^$/m$' '/^\[code\.change\.1\]/;/^\[code\.test\.1\]/-1m$' ,p Q | ed -s file.cfg

    Se você estiver satisfeito com o resultado/saída

    • Altere Qpara wse for necessária edição no local .

    • Remova o ,ppara silenciar a saída.

    • Veja POSIX ed.

    • Veja GNU ed.

    • 2

  3. Supondo que a entrada seja um arquivo de apenas 2 blocos, como mostrado no exemplo da pergunta, então usando qualquer awk:

    $ awk -v RS= -v OFS='\n\n' '{v[NR]=$0} END{print v[2], v[1]}' file.cfg
[code.test.1]
ls -la filepath
pwd
find . -name filename

[code.change.1]
file.path=filename
file.contact=manager
file.active=TRUE

    ou:

    $ awk -v RS= -v OFS='\n\n' 'NR==1{s=$0; next} {print $0, s}' file.cfg
[code.test.1]
ls -la filepath
pwd
find . -name filename

[code.change.1]
file.path=filename
file.contact=manager
file.active=TRUE

    ou com GNU awk para RS multi-char:

    $ awk -v RS='^$' -F'\n\n' -v OFS='\n' '{print $2, $1}' file.cfg
[code.test.1]
ls -la filepath
pwd
find . -name filename

[code.change.1]
file.path=filename
file.contact=manager
file.active=TRUE
    • 1

relate perguntas