Início / coding / Perguntas / 79108104
Accepted
PTQuoc
Asked: 2024-10-21 05:40:50 +0800 CST

Função IFS do Excel

  • 772

Eu uso a função IFS do Excel para adicionar *

A função de trabalho é:

=IF(G5="","",FIXED(G5,1)&IFS(ABS(G6)>=2.575,"***",ABS(G6)>=1.96,"**",ABS(G6)>=1.645,"*",ABS(G6)<1.645,""))

Como vejo que ABS(G6)<1.645 é redundante, decidi abandoná-lo

=IF(G5="","",FIXED(G5,1)&IFS(ABS(G6)>=2.575,"***",ABS(G6)>=1.96,"**",ABS(G6)>=1.645,"*"))

Mas a fórmula encontrou um problema, retornou #N/A

Espero que alguém possa me explicar por que a remoção da peça causa o problema?

excel

2 respostas

  1. Best Answer

    Você precisa fornecer a ramificação "else" para IFS:

    =IF(G5="",
  "",
  FIXED(G5,1)&IFS(
    ABS(G6)>=2.575,"***",
    ABS(G6)>=1.96,"**",
    ABS(G6)>=1.645,"*",
    TRUE,""
  )
)

    Ler comentários na função IFS :

    Para especificar um resultado padrão, insira TRUE para seu argumento logical_test final. Se nenhuma das outras condições for atendida, o valor correspondente será retornado.

    • Se um argumento logical_test for fornecido sem um value_if_true correspondente, esta função mostrará uma mensagem de erro "Você inseriu poucos argumentos para esta função".
    • Se um argumento logical_test for avaliado e resultar em um valor diferente de TRUE ou FALSE, esta função retornará um erro '#VALUE!'.
    • Se nenhuma condição VERDADEIRA for encontrada, esta função retornará o erro '#N/D'.

    Então, você tem '#N/A' devido a ABS(G6)<1.645e não há tal condição na lista.

    Além disso, você pode suprimir '#N/A' de outra maneira:

    =IF(G5="",
  "",
  FIXED(G5,1)&IFNA(
    IFS(
      ABS(G6)>=2.575,"***",
      ABS(G6)>=1.96,"**",
      ABS(G6)>=1.645,"*"
    ),
    ""
  )
)
    • 1

  2. Sua primeira fórmula está completa, enquanto a segunda não. A função IFS precisa cobrir todas as situações possíveis, então na segunda fórmula, ela não sabe o que fazer quando o valor G6 é menor que 1,65. A documentação sobre IFS afirma que você pode usar uma cláusula ELSE para manipular qualquer valor não coberto pelos intervalos especificados. Confira este link: https://www.ablebits.com/office-addins-blog/excel-ifs-function/

    • 0

relate perguntas