Início / coding / Perguntas / 79018379
Accepted
hoa tran
Asked: 2024-09-24 19:25:20 +0800 CST

Como somar várias colunas com várias condições

  • 772

Tenho uma tabela como a abaixo:

Certificado de Autenticação 100 101 102 200 201 202 300
11000000000 1000 1200 1100 1000 1200 1100 1800
11200100000 1500 1400 1300 1500 1400 1300 1700

Quero somar 100, 101, 102para um grupo e 200, 201, 202para um grupo e 300para um grupo. Abaixo está minha Saída esperada:

Primeira Tabela:

Certificado de Autenticação 100+ Mais de 200 300
11000000000 3300 3300 1800
11200100000 4200 4200 1700

Segunda Tabela: Supondo que os 2 COAs pertencem a 1 grande COA e eu quero somar os totais desses dois grandes COAs por grupo.

Certificado de Autenticação 100+ Mais de 200 300
11000000000 e 11200100000 7500 7500 3500

Como posso obter a saída esperada? Obrigado.

excel

2 respostas

  1. Best Answer

    Para a primeira tabela:=SUM(IF((LEFT($B$1:$H$1,1)=LEFT(B$15,1))*($A16=$A$2:$A$3),$B$2:$H$3,""))

    Esta fórmula pode ser arrastada para a direita e para baixo conforme necessário.

    Consulte a imagem abaixo para ver o que cada argumento contém/se refere.

    Fórmula Tabela 1 Tabela de saída 1

    Para a Tabela 2:=SUM(IF((LEFT($B$1:$H$1,1)=LEFT(B19,1))*((CHOOSEROWS(TEXTSPLIT($A20,," & "),1)*1=$A$2:$A$3)+(CHOOSEROWS(TEXTSPLIT($A20,," & "),2)*1=$A$2:$A$3)),$B$2:$H$3,""))

    Aqui você deve garantir que seu COA esteja sempre formatado da mesma forma: ### & ###.

    Fórmula Tabela 2 Tabela de saída 2

    Suspeito que possa haver uma maneira mais fácil/melhor de fazer a Tabela 2, mas funciona.

    • 2

  2. Usando SUMPRODUCTe MAKEARRAY:

    Primeiro

    =LET(
    tbCOA, A1:H3,
    coa, DROP(INDEX(tbCOA, , 1), 1),
    amts, DROP(tbCOA, 1, 1),
    amt_header, DROP(INDEX(tbCOA, 1, ), , 1),
    amt_group, --SUBSTITUTE(B7:D7, "+", ""),
    sum_amt, LAMBDA(coa_row, amt_grp_col,
        SUMPRODUCT(
            amts * (INDEX(coa, coa_row, 1) = coa) *
                IFERROR(
                    N(XMATCH(amt_header, amt_group, -1) = amt_grp_col),
                    0
                )
        )
    ),
    MAKEARRAY(ROWS(coa), COLUMNS(amt_group), sum_amt)
)

    Primeiro resultado

    Segundo

    =LET(
    tbCOA, A1:H3,
    coa, DROP(INDEX(tbCOA, , 1), 1),
    coas, A14,
    amts, DROP(tbCOA, 1, 1),
    amt_header, DROP(INDEX(tbCOA, 1, ), , 1),
    amt_group, --SUBSTITUTE(B7:D7, "+", ""),
    sum_amt, LAMBDA(coa_row, amt_grp_col,
        SUMPRODUCT(
            amts *
                ISNUMBER(XMATCH(coa, TRIM(TEXTSPLIT(INDEX(coas, coa_row, 1), "&")))) *
                IFERROR(N(XMATCH(amt_header, amt_group, -1) = amt_grp_col), 0)
        )
    ),
    MAKEARRAY(ROWS(coas), COLUMNS(amt_group), sum_amt)
)

    Segundo resultado

    • 1

relate perguntas