Início / coding / Perguntas / 79005658
Accepted
Jelena Popovic
Asked: 2024-09-20 15:13:01 +0800 CST

Comparando campos de texto que contêm datas no Planilhas Google

  • 772

Estou recebendo as datas no seguinte formato:

5.9.2024. então d.m.yyyy.

e preciso usar esse campo na fórmula da consulta para verificar se essa data está entre duas datas (por exemplo >=5.9.2024, . e <=12.9.2025. são os valores das células para o intervalo de datas).

Estou com dificuldades para converter a célula de texto em data para poder fazer essa comparação.

Imagem

Tentei todas as fórmulas diferentes para conversão de texto em data, mas nada funciona.

=query(A4:B, "select Col1 where Col2>='"&$A2&"'AND Col2<='"&$B2&"'")
date

4 respostas

  1. Corrigindo o formato da data para comparação

    Parece que você está tendo problemas para converter a string. É por isso que você está tendo problemas durante a comparação.

    Tente converter suas datas usando esta fórmula.

    =LET(dates, SPLIT(A1, "."), dd, CHOOSECOLS(dates, 1), mm, CHOOSECOLS(dates,2), yyyy, CHOOSECOLS(dates,3), DATE(yyyy,mm,dd))

    Antes de fazer qualquer comparação, ele deve funcionar como esperado.

    Você também pode tentar esta fórmula para processar várias linhas.

    Use BYROWe coloque a fórmula dentro de um LAMBDA function.

    =BYROW(A1:A7, LAMBDA(r, LET(dates, SPLIT(r, "."), dd, CHOOSECOLS(dates, 1), mm, CHOOSECOLS(dates,2), yyyy, CHOOSECOLS(dates,3), DATE(yyyy,mm,dd))))

    Exemplo de saída:

    Saída

    Nota : Isto é para converter sua string para uma Data que pode ser usada na parte de comparação da fórmula. Se precisar de mais informações sobre como trabalhar com esta fórmula, sinta-se à vontade para perguntar nos comentários.

    Referência:

    Data

    • 1
  2. Best Answer

    Você pode tentar a seguinte fórmula:

    =--TEXTJOIN("/",1,CHOOSECOLS(SPLIT(A1,"."),2,1,3))

    Em seguida, aplique o formato de data desejado às células.

    insira a descrição da imagem aqui

    Para converter uma coluna inteira, use-

    =MAP(A1:A,LAMBDA(x,IF(x="",,--TEXTJOIN("/",1,CHOOSECOLS(SPLIT(x,"."),2,1,3)))))

    insira a descrição da imagem aqui

    • 1

  3. Para obter datas diretamente da sua primeira coluna, tente-

    =LET(x,CHOOSECOLS(SPLIT(A2," "),-1),--TEXTJOIN("/",1,CHOOSECOLS(SPLIT(x,"."),2,1,3)))

    Para a coluna inteira, tente-

    =MAP(A2:A,LAMBDA(z,IF(z="",,LET(x,CHOOSECOLS(SPLIT(z," "),-1),--TEXTJOIN("/",1,CHOOSECOLS(SPLIT(x,"."),2,1,3))))))

    insira a descrição da imagem aqui

    • 0

  4. Uma alternativa para corrigir as datas e despejar as Colunas A and Bna planilha a fórmula na célula D4é:

    =ARRAYFORMULA(QUERY({A4:B, IF(B4:B<>"",REGEXREPLACE(B4:B,"(\d+).(\d+)\.(\d+)\.","$2/$1/$3"),"")},"Select Col1, Col3 Where Col1 Is Not Null"))

    .

    insira a descrição da imagem aqui

    • 0

relate perguntas