Início / coding / Perguntas / 78980044
Accepted
bill999
Asked: 2024-09-13 05:45:50 +0800 CST

Como dividir uma string em apenas duas partes (e não descartar outras partes)

  • 772

Digamos que eu tenha estes dados:

clear all
set obs 2
gen title = "dog - cat - horse" in 1
replace title = "chicken - frog - ladybug" in 2
tempfile data
save `data'

Posso dividi-los em três partes:

use `data', clear
split title, p(" - ")

E posso dividi-los em duas partes, descartando a terceira parte:

use `data', clear
split title, p(" - ") limit(2)

Existe uma solução pronta para dividir em apenas duas partes, mas agrupar tudo depois do primeiro caractere de divisão (traço neste caso) na segunda variável? Em R, eu usaria separatecom a extra="merge"opção (veja tidyr separa apenas as primeiras n instâncias ).

Em outras palavras, para a primeira linha, gostaria que as primeiras observações title1fossem doge para title2fossem cat - horse.

Percebo que isso é possível usando código personalizado (veja Stata split string into parts ), mas espero um comando simples como o split/R do Stata separatepara atingir meu objetivo.

string

1 respostas

  1. Best Answer

    No momento, esta não é uma opção no splitcomando oficial. (Divulgação completa: eu era o autor anterior.)

    Você poderia simplesmente escrever seu próprio comando. Este precisa de mais generalidade e mais verificações de erro, mas ele faz o que eu acho que você quer com seu exemplo de dados. Detalhe: é desejado cortar espaços?

    clear all
set obs 2
gen title = "dog - cat - horse" in 1
replace title = "chicken - frog - ladybug" in 2

gen title1 = trim(substr(title, 1, strpos(title, "-") - 1))
gen title2 = trim(substr(title, strpos(title, "-") + 1, .))

program split2
    syntax varname(string), parse(str) [suffixes(numlist int min=2 max=2)]
    
    if "`suffixes'" == "" local suffixes "1 2"
    tokenize "`suffixes'"
    
    gen `varlist'`1' = trim(substr(`varlist', 1, strpos(`varlist', "`parse'") - 1))
    gen `varlist'`2' = trim(substr(`varlist', strpos(`varlist', "`parse'") + strlen("`parse'"), .))
end 

split2 title, parse("-") suffixes(3 4)

list 
    
     +--------------------------------------------------------------------------------+
     |                    title    title1           title2    title3           title4 |
     |--------------------------------------------------------------------------------|
  1. |        dog - cat - horse       dog      cat - horse       dog      cat - horse |
  2. | chicken - frog - ladybug   chicken   frog - ladybug   chicken   frog - ladybug |
     +--------------------------------------------------------------------------------+

    Note também a egenfunção ends()e suas opções headand tail. Usar isso precisaria de duas chamadas. Ela gera apenas uma variável por vez.

    • 1

relate perguntas