Existe uma maneira no Excel de ir do ponto a ao ponto b

Possível usando a função MATCH:

Digamos que você tenha sua primeira tabela na Planilha1.

Na planilha2, nomeie suas colunas exatamente como você fez:

Agora, na célula B2, copie e cole o seguinte:

=IF(SUM(ISNUMBER(MATCH(Sheet1!$A$2:$A$5,$A2,0))*ISNUMBER(MATCH(Sheet1!$B$2:$B$5,B$1,0)))>0,"x","")

Em seguida, arraste o canto da célula para preencher toda a tabela.

Detalhamento da célula B2

Estamos tentando ver se, para cada célula da coluna A da Planilha1, corresponde ao conteúdo do cabeçalho da linha (servidor1):

MATCH(Sheet1!$A$2:$A$5,$A2,0)

Isso é avaliado como {1, 1, #N/A, #N/A}.

Mantemos então apenas as células que são números usando ISNUMBER(observe a colocação do sinal $ em $A2 que bloqueia a coluna, mas não a linha, para continuar apontando para o cabeçalho da coluna quando arrastamos o canto da célula):

ISNUMBER(MATCH(Sheet1!$A$2:$A$5,$A2,0))

Isso é avaliado como {TRUE, TRUE, FALSE, FALSE}.

Fazemos o mesmo para o cabeçalho da coluna (desta vez bloqueamos a linha B$1 para manter o cabeçalho) e multiplicamos os dois arrays. Acabamos tendo {TRUE * TRUE, TRUE * FALSE, FALSE * TRUE, FALSE * FALSE}, que é avaliado como {1, 0, 0, 0}.

Somamos todos esses números usando SUMe, de forma simples, IFpodemos dizer que se essa soma for um ou superior, então quero exibir um x.

Se você tiver Excel 365:

=LET(
    serverdata, A2:A5,
    servicesdata, B2:B5,
    servers, UNIQUE(serverdata),
    services, TRANSPOSE(UNIQUE(servicesdata)),
    matchMatrix, IF(COUNTIFS(serverdata, servers, servicesdata, services) > 0, "x", ""),
    VSTACK(HSTACK("", services), HSTACK(servers, matchMatrix))
)

serverdata: Faça referência ao intervalo de entrada do servidor

servicesdata: Faça referência ao intervalo de entrada de serviços

servidores: extraia nomes de servidores exclusivos de serverdata

serviços: Extraia nomes de serviços exclusivos de servicesdata e transponha-os para um formato de linha.

matchMatrix: verifique cada combinação de servidores e serviços. Se for encontrada uma correspondência (ou seja, o servidor oferece o serviço), coloque um “x”; caso contrário, deixe a célula em branco.

VSTACK: Empilhe a linha do cabeçalho (serviços) no topo da matriz de correspondência começando com uma célula em branco

HSTACK: Empilhe os nomes dos servidores à esquerda da matriz de correspondência.

Preencha os x quando houver uma correspondência

É conhecida como tabela dinâmica:

Existem várias etapas para criar a tabela.