Início / coding / Perguntas / 78827240
Accepted
Mark S.
Asked: 2024-08-03 05:06:29 +0800 CST

Xlookup multicondicional com entradas de matriz de derramamento

  • 772

Eu tenho uma matriz com várias colunas que são intervalos de derramamento. Preciso usar cada coluna para fazer um xlookup multicondicional (ou fórmula/resultado semelhante) que forneça uma faixa de resultados dos resultados. Usei sumifs para obter resultados, mas quando uma célula está vazia, gostaria que ela permanecesse vazia, onde os resultados dos sumifs dão 0% quando uma célula está vazia.

A aplicação real disso será colocada em uma fórmula LET e cada um dos derramamentos no xlookup será uma saída de escolha.

=XLOOKUP(1,($C$3#=$C$12:$C$15)*($D$3#=D12:D15),$E$12:$E$15,"",0)

=SUMIFS($E$12:$E$15,$C$12:$C$15,C3#,$D$12:$D$15,D3#)

Na imagem, as bordas indicam uma matriz de derramamento. Os resultados esperados são inseridos manualmente.

imagem

excel

2 respostas

  1. Best Answer

    Você poderia tentar usar a seguinte fórmula:

    insira a descrição da imagem aqui

    =MAP(C3#,D3#,LAMBDA(α,δ, 
 XLOOKUP(1,(α=C12:C15)*(δ=D12:D15),
 IF(E12:E15="","",E12:E15),"")))

    Ou,

    =LET(a, SUMIFS(E12:E15,C12:C15,C3#,D12:D15,D3#), IF(a=0,"",a))

    Ou,

    =LET(
     a, FILTER(E12:E15,COUNTIFS(C3#,C12:C15,D3#,D12:D15)),
     IF(a=0,"",a))

    Ou,

    =XLOOKUP(C3#&"|"&D3#,C12:C15&"|"&D12:D15,IF(E12:E15=0,"",E12:E15))
    • 2

  2. Isso funcionaria, Marcos?

    =IF(LEN(TRIM($E$12#)), SUMIFS($E$12#,$C$12#,C3#,$D$12#,D3#),"")

    Fórmula e resultado

    Ou

    Matriz de derramamento 2

    • 1

relate perguntas