VBA JsonConverter.ParseJson Analisar Jason me dando erro de tipo incompatível

Usando JSonParser, os valores necessários podem ser extraídos da sua string JSON de amostra da seguinte maneira;

Sub Test()
    Dim strJSON As String, JSon As Object, id As String, membersValue As String, rolesValue As String
    
    strJSON = "{""schemas"":[""urn:ietf:params:scim:schemas:core:2.0:Group"",""urn:sap:params:scim:schemas:extension:sac:2.0:group-roles"",""urn:sap:params:scim:schemas:extension:sac:2.0:group-custom-parameters""],""id"":""bef561ee-5a1e-420e-a1e\n4-4f624c96af6e"",""meta"":{""resourceType"":""Group"",""created"":""2024-07-25T14:17:53.215Z"",""lastModified"":""2024-08-01T14:31:29.632Z"",""location"":""/api/v1/scim2/Groups/bef561ee-5a1e-420e-a1e4-4f624c96af6e""},""displayName"":""TEAM_TEST"",""members"":[{""value"":""f27dcbb9-df9a-46b2-b23a-3b35d5a8bdff"",""type"":""User"",""display"":""Test_FirstName1 TEST_Familyname1"",""$ref"":""/api/v1/scim2/Users/f27dcbb9-df9a-46b2-b23a-3b35d5a8bdff""}],""urn:sap:params:scim:schemas:extension:sac:2.0:group-roles"":{""roles"":[{""value"":""PROFILE:t.4:VIEW_USER"",""display"":""VIEW_USER""}]},""urn:sap:params:scim:schemas:extension:sac:2.0:group-custom-parameters"":{""description"":""Team Test""}}"
      
    Set JSon = ParseJson(strJSON)

    id = JSon("id")
    
    membersValue = JSon("members")(1)("value")
    
    rolesValue = JSon("urn:sap:params:scim:schemas:extension:sac:2.0:group-roles")("roles")(1)("value")

    
    MsgBox "id = " & id & vbCrLf & "members.value = " & membersValue & vbCrLf & "roles.value = " & rolesValue
End Sub

A idchave está associada a um único valor, não a um objeto ou array, então

tempName = JsonData("id")(0)
MsgBox (tempName)   'no parens as noted in BigBen's comment

deveria estar

tempName = JsonData("id")
MsgBox tempName

Achei muito mais fácil acessar especificamente diferentes partes de um objeto JSON individualmente em cada etapa. Isto ajudou a evitar a maioria dos problemas e confusões entre os diferentes objetos (Dicionários e Coleções). Eu uso essa referência o tempo todo, ela provou ser de grande ajuda.

Então, com base nesse conselho e usando a referência vinculada, criei o código de teste abaixo para mostrar como acessar diferentes partes da sua estrutura JSON e executar loops quando for apropriado.

Option Explicit

Sub test()
    Dim strJSON As String
    strJSON = GetJSONString
    
    Dim json As Object
    Set json = ParseJson(strJSON)
    
    Dim resources As Collection
    Set resources = GetCollection(json, "Resources")
    
    Dim junk As Collection
    Set junk = GetCollection(json, "junk")
    
    Dim resource As Dictionary
    For Each resource In resources
        Debug.Print "----- Resource:"
        Dim schemas As Collection
        Set schemas = GetCollection(resource, "schemas")
        
        Dim i As Long
        For i = 1 To schemas.Count
            Debug.Print "   Schema(" & i & ") = " & schemas(i)
        Next i
        
        Dim id As String
        id = resource("id")
        
        Dim meta As Dictionary
        Set meta = GetDictionary(resource, "meta")
        If Not meta Is Nothing Then
            Dim metaEntry As Variant
            For Each metaEntry In meta
                Debug.Print "   Meta Entry: " & metaEntry & " = " & meta(metaEntry)
            Next metaEntry
        End If
        
        Dim displayName As String
        displayName = resource("displayName")
        
        Dim members As Collection
        Set members = GetCollection(resource, "members")
        If Not members Is Nothing Then
            Dim member As Variant
            Debug.Print "   member count = " & members.Count
            For i = 1 To members.Count
                Dim memberEntry As Dictionary
                Set memberEntry = members(i)
                Dim entryKey As Variant
                For Each entryKey In memberEntry
                    Debug.Print "   For member(" & i & "): " & entryKey & " = " & memberEntry(entryKey)
                Next entryKey
            Next i
        End If
    Next resource
End Sub

Function GetCollection(ByRef jsonObj As Object, ByVal entryName As String) As Collection
    On Error Resume Next
    Set GetCollection = jsonObj(entryName)
    If GetCollection Is Nothing Then
        Debug.Print "The requested object " & entryName & " does not exist in the referenced Collection"
    End If
End Function

Function GetDictionary(ByRef jsonObj As Object, ByVal entryName As String) As Dictionary
    On Error Resume Next
    Set GetDictionary = jsonObj(entryName)
    If GetDictionary Is Nothing Then
        Debug.Print "The requested object " & entryName & " does not exist in the referenced Dictionary"
    End If
End Function

Function GetJSONString() As String
    Dim fileHandle As Integer
    Dim filename As String
    filename = "C:\temp\test.json"
    fileHandle = FreeFile
    Open filename For Input As FreeFile
    GetJSONString = Input(LOF(fileHandle), fileHandle)
    Close fileHandle
End Function