Início / coding / Perguntas / 78782952
Accepted
sasos
Asked: 2024-07-23 18:36:13 +0800 CST

Excel VBA - mova dados para outra tabela com base no valor da matriz

  • 772

Eu tenho 2 tabelas do Excel:

Processo de tabela:

insira a descrição da imagem aqui

E pedidos de mesa:

insira a descrição da imagem aqui

Gostaria de preencher a coluna OrderID da tabela Process com os OrderIDs da tabela Orders - quando existe uma Tag com o valor de ProcessID. Tenho certeza de que isso pode ser feito com VBA, mas não tenho o conhecimento prévio necessário, portanto, qualquer ajuda será muito apreciada. Eu estava pesquisando matrizes do Excel, então se eu precisar alterar as Tags para algo como {217.218.229.230} - isso eu sei fazer :) Mas a partir daí?

Este é o resultado final que estou procurando:

insira a descrição da imagem aqui

Uma imagem apenas para resposta à resposta do CLR, pois não consigo anexá-la ao comentário: insira a descrição da imagem aqui

excel

3 respostas

  1. Best Answer

    Você pode fazer isso com uma fórmula:

    =IFERROR(INDEX(OrderTab!A:A,MATCH("*|"&A2&"|*","|"&OrderTab!B:B&"|",0)),"Not Found")

    Supondo que sua tabela Order esteja em uma planilha chamada OrderTab. Mude isso.

    Resultado:

    insira a descrição da imagem aqui

    • 2

  2. Provavelmente existe uma maneira mais fácil com Excel365, mas pelo menos em versões mais antigas isso funciona:

    insira a descrição da imagem aqui

    Fórmula na coluna C:

    =INDEX($E$2:$E$9;SUMPRODUCT(--(IFERROR(SEARCH("|"&A2&"|";"|"&$F$2:$F$9&"|");0)>0)*ROW($F$2:$F$9))-1)

    Para que isso funcione, você precisa inserir a fórmula como uma fórmula de matriz pressionando CTRL+ SHIFT+ENTER

    • 1

  3. Se você possui o Microsoft 365, pode tentar isso (não competindo por uma resposta curta aqui :)

    • para cada ID de processo
      MAP(process_ids, LAMBDA(process_id
    • em tags para IDs de pedidos, para tags para cada ID de pedido
      MAP(tags_for_order_ids, LAMBDA(tags_for_order_id,
    • divida as tags e procure por correspondências
      OR(process_id = TRIM(TEXTSPLIT(tags_for_order_id, "|")) `
    • retornar o ID do pedido se correspondido, removendo as não correspondências ( #NA) comTOCOL
    • Digite o seguinte na primeira célula ( C2no exemplo), não há necessidade de preencher
    =LET(
    process_ids, TRIM(A2:A9),
    tags_for_order_ids, OrderTab!B2:B9,
    order_ids, OrderTab!A2:A9,
    MAP(
        process_ids,
        LAMBDA(process_id,
            IFERROR(
                TOCOL(
                    IF(
                        MAP(
                            tags_for_order_ids,
                            LAMBDA(tags_for_order_id,
                                OR(
                                    process_id =
                                        TRIM(TEXTSPLIT(tags_for_order_id, "|"))
                                )
                            )
                        ),
                        order_ids,
                        NA()
                    ),
                    3
                ),
                "no match"
            )
        )
    )
)

    Fórmula e resultado

    Inicie uma nova linha de texto dentro de uma célula no Excel - Suporte da Microsoft

    • 0

relate perguntas