Início / coding / Perguntas / 78749382
Accepted
nemo nemo
Asked: 2024-07-15 18:38:39 +0800 CST

Como usar expressões simbólicas produzidas por uma função para definir outra função?

  • 772

Estou tentando fazer uma função de derivação simbólica no esquema Chez. Funciona bem (a simplificação ainda não está sendo feita):

(define (derive var expr)
;; var is the direction in which you would like to derive
  (if (list? expr)
      (case (car expr)
        ('+    (sum-rule var expr))
        ('-    (sub-rule var expr))
        ('*    (prod-rule var expr))
        ;; other rules
        (else  (atomic-rule var expr )))
      (atomic-rule var expr)))

(define (atomic-rule var expr)
  (if (list? expr)
      expr
      (if (eqv? var expr)
          1
          0)))

(define (sum-rule var expr)
  (let ((args (cdr expr)))
    `(+ ,@(map (lambda (e) (derive var e)) args))))

(define (sub-rule var expr)
  (let ((args (cdr expr)))
    `(- ,@(map (lambda (e) (derive var e)) args))))

(define (prod-rule var  expr)
  (let* ((args (cdr expr))
         (f (car args))
         (g (cadr args)))
    `(+ (* ,f ,(derive var g))
        (* ,g ,(derive var f)))))

Eu posso fazer (derive 'x '(+ (* x x) (* x y)))e acertar (+ (+ (* x 1) (* x 1)) (+ (* x 0) (* y 1)))o que está correto. Mas também gostaria de criar programaticamente funções que retornem valores numéricos dessas expressões.

Minhas tentativas falharam:

(define (lambda-derive var expr)
  (let ([derivative (derive var expr)])
    (lambda (var) derivative)))

((lambda-derive 'x '(* x x)) 2) => (+ (* x 1) (* x 1)) ;; should be 4

(define-syntax lbd-macro
  (lambda (context)
    (syntax-case context ()
      [(k expr var )
       (with-syntax ([new-var (datum->syntax #'k (syntax->datum #'var))])
         #'(lambda (new-var) expr))])))


((lbd-macro (derive 'x '(* x x)) x) 2) => (+ (* x 1) (* x 1)) ;; should be 4

Sinto que estou perdendo algo muito óbvio. Alguém pode fornecer uma luz? (Sim, eu sei que as tentativas não cobrem casos multivariados)

==EDITAR==

Tive uma noite de sono ruim e decidi continuar trabalhando, e cheguei a uma solução semelhante à que @ignis volens descreveu, embora usando tabelas hash e sendo muito mais hacky:

(define (lambda-aux variables vals expr)
  (let ((ht (make-eqv-hashtable (length variables))))
    (for-each (lambda (k v) (hashtable-set! ht k v)) variables vals)
    (let loop ((expr expr))
      (if (list? expr)
          (let ((op (car expr))
                (args (map loop (cdr expr))))
            (cons op args))
          (let ((variable (hashtable-ref ht expr #f)))
            (if variable
                variable
                (if (number? expr)
                    expr
                    (error "variable not found"))))))))

(define-syntax lambda-derive
  (syntax-rules ()
    [(_ expr var var* ...)
     (lambda (var var* ...) (eval (lambda-aux '(var var* ...) (list var var* ...) (derive 'var 'expr) )))]))

Que pode ser usado assim:

(define my-test-derivative
  ;;f(x,y) = x^2 + x * y
  ;;df/dx (x,y) = 2*x + y
  (lambda-derive (+ (* x y) (* x x)) x y))
(my-test-derivative 2 2) => 6
(my-test-derivative 8 2) => 18
;; ...
scheme

1 respostas

  1. Best Answer

    Este é um caso em que você deseja cerrar os dentes e usar eval:

    (eval `(lambda (x) ,(derive 'x '(* x x))) (scheme-report-environment 5))

    retornará uma função de um argumento que avaliará a derivada de (* x x)para um determinado valor de x(estou assumindo R5RS aqui, pois não tenho Chez Scheme):

    > (let ((d (eval `(lambda (x) ,(derive 'x '(* x x))) (scheme-report-environment 5))))
    (d 1))
2

    Ou, possivelmente melhor (e certamente com mais segurança), você pode escrever um avaliador de expressão simbólica. Novamente este é R5RS:

    (define (evaluate-symbolic-expression expression bindings)
  ;; Evaluate a symbolic expression in the presence of bindings
  (cond
    ((number? expression)
     expression)
    ((symbol? expression)
     (let ((found (assq expression bindings)))
       (if found
           (evaluate-symbolic-expression (cadr found) bindings)
           expression)))
    ((pair? expression)
     (apply-symbolic-operator
      (car expression)
      (map (lambda (e) (evaluate-symbolic-expression e bindings))
           (cdr expression))
      bindings))
    (else
     expression)))

(define (all-numbers? l)
  (cond
    ((null? l)
     #t)
    ((number? (car l))
     (all-numbers? (cdr l)))
    (else
     #f)))

(define (apply-symbolic-operator op args bindings)
  (if (all-numbers? args)
      (let ((f (assq op bindings)))
        (if f
         (apply (cadr f) args)
         `(,op ,@args)))
      `(,op ,@args)))

(define arithmetic-operator-bindings
  `((+ ,+)
    (- ,-)
    (* ,*)
    (/ ,/)))

    E agora

    > (evaluate-symbolic-expression
   (derive 'x '(* x x))
   (append '((x 4)) arithmetic-operator-bindings))
8

    evaluate-symbolic-expressionpoderia ser escrito de forma mais clara: comecei a implementar um avaliador para o que era essencialmente um minúsculo Lisp-2, mas eu mudei e tive preguiça de refazer tudo.

    • 2

relate perguntas