Obtenha o primeiro e o último número que ocorre em uma string (de texto) em uma célula

Apenas uma solução alternativa não é mais curta como a muito bem respondida por Pb Sir

=--TEXTSPLIT(A2,TEXTSPLIT(A2,SEQUENCE(10)-1,,1),,1)

Além disso, não estou muito familiarizado com o assunto REGEX, mas seguindo as soluções do JvdV Sir sobre o mesmo tópico, acho que isso pode funcionar, e pode-se usar o seguinte, se durante a escrita o Office Insiders estiver habilitado:

=--REGEXEXTRACT(A2,"\d+",1)

Ou, se você quiser fazer isso de uma só vez para todo o intervalo:

=--REGEXEXTRACT(A2:A4,"\d+"&{"","$"})

Isso funciona porque forçamos o Excel a retornar duas colunas devido à adição de uma string vazia à primeira E uma âncora de linha final à segunda coluna. Dessa forma, retornamos a primeira ocorrência de 1+ dígitos na 1ª coluna e os 1+ dígitos que ficam no final de uma string na 2ª coluna.

Sinta-se à vontade para fazer edições em minha resposta, REGEXse alguém achar que não está correta, eu fiz issoCommunity Wiki

=TEXTSPLIT(A2,VSTACK("-",CHAR(SEQUENCE(58,,65))),,1)

Isso divide o texto em caracteres maiúsculos ou minúsculos e o sinal de menos (e alguns caracteres extras não utilizados entre a sequência de caracteres maiúsculos e minúsculos).

Na verdade, isso é feito por texto ou sinal de menos:

=TEXTSPLIT(UPPER(A2),CHAR(VSTACK(45,SEQUENCE(26,,65))),,1)

Para Excel mais antigo, recomendo o uso de auxiliares ou intervalos nomeados: Helper1 em B2:=MAX(IFERROR(FIND(CHAR(ROW($65:$90)),UPPER(A2)),0))+1

Ajudante2 em C2: =FIND("-",A2)

Primeiro número: =--MID(A2,B2,C2-B2)

Segundo número: =--RIGHT(A2,LEN(A2)-C2)

Para versões anteriores do Excel:

First: =MID(A2,MIN(FIND({0;1;2;3;4;5;6;7;8;9},A2&"0123456789")),FIND("-",A2)-MIN(FIND({0;1;2;3;4;5;6;7;8;9},A2&"0123456789")))

Last: =MID(A2,FIND("-",A2)+1,255)

O exemplo acima retorna as sequências de dígitos como texto. Se você preferir que sejam números reais, prefixe cada fórmula com o unário duplo ( --) para converter.

Esta fórmula aceita qualquer comprimento de números.

B20: =LET(perchar,MID(TEXTBEFORE(A20,"-"),SEQUENCE(1,LEN(TEXTBEFORE(A20,"-"))),1), TEXTJOIN("",TRUE,IF(ISNUMBER(--perchar),perchar,"")))

C20:=TEXTAFTER(A20,"-")

Obrigado por postar essas perguntas para praticar :)

Tentando com este método (Microsoft 365): substitua todos os não dígitos por espaços ( IF(ISNUMBER(0 + c_), c_, space)e divida.

=LAMBDA(rows_,
    LET(
        first_and_last_numbers, LAMBDA(input,
            LET(
                space, " ",
                split, TEXTSPLIT(
                    TRIM(
                        CONCAT(
                            MAP(
                                MID(input, SEQUENCE(LEN(input)), 1),
                                LAMBDA(c_, IF(ISNUMBER(0 + c_), c_, space))
                            )
                        )
                    ),
                    space
                ) + 0,
                IFERROR(
                    IF(
                        COLUMNS(split) >= 2,
                        HSTACK(TAKE(split, , 1), TAKE(split, , -1)),
                        EXPAND(split, , 2)
                    ),
                    "None"
                )
            )
        ),
        DROP(REDUCE("", rows_, LAMBDA(a, c, VSTACK(a, first_and_last_numbers(c)))), 1)
    )
)(A2:A4)

Típico, não resisti ao desafio:

LEFT(SUBSTITUTE(A2,"Top",),FIND("-",SUBSTITUTE(A2,"Top",),1)-1)*1

SUBSTITUTE(RIGHT(SUBSTITUTE(A2,"Top",),FIND("-",SUBSTITUTE(A2,"Top",),1)),"-",)*1

Não testei além dos exemplos que você deu, mas a classificação de 3 dígitos é deixada para você.