Início / coding / Perguntas / 78575007
Accepted
Enigmativity
Asked: 2024-06-04 19:08:45 +0800 CST

Expanda os valores em linhas para distribuir valores

  • 772

Eu tenho uma série de valores no Excel.

A linha superior é um número base. A segunda linha mostra quantos valores em cada número da série. A terceira linha é o valor total desse número na série.

Entrada

Observe que no meu exemplo os números na terceira linha somam 42 (um acaso completo!).

Quero expandir esses números assim:

Saída

O número da série é a base mais a sequência de 1 até o número da segunda linha. Então o valor é o número do valor dividido pelo número na sequência atual.

Observe que a linha final soma o mesmo que a linha de entrada. Estou distribuindo esses números uniformemente.

A verdadeira aplicação aqui é expandir os valores de um orçamento feito mensalmente pela quantidade de dias do mês e distribuir os números por dia. Pretendo então agrupar por semanas.

Estou lutando para fazer com que até mesmo a expansão mais básica funcione:

=HSTACK(BYCOL(R8C3:R8C5,LAMBDA(n,SEQUENCE(n,1))))

Eu adoraria ser apontado na direção certa.

excel

1 respostas

  1. Best Answer

    Não tenho certeza se é isso que você está pedindo, no entanto, descobri isso usando TOROW()+ SEQUENCE()+XLOOKUP()

    insira a descrição da imagem aqui

    • Fórmula usada na célulaA6

    =LET(
     α, A2:C2,
     δ, SEQUENCE(MAX(α)),
     VSTACK(TOROW(IF(δ<=α,A1:C1+δ,NA()),2,1),
     TOROW(IF(δ<=α,A3:C3/XLOOKUP(A1:C1,A1:C1,α),NA()),2,1)))

    Versão sem clube:

    insira a descrição da imagem aqui

    • Fórmula usada na célulaA6

    =LET(α, A2:C2, δ, SEQUENCE(MAX(α)), TOROW(IF(δ<=α,A1:C1+δ,NA()),2,1))

    • Fórmula usada na célulaA7

    =LET(α, A2:C2, δ, SEQUENCE(MAX(α)), TOROW(IF(δ<=α,A3:C3/XLOOKUP(A1:C1,A1:C1,α),NA()),2,1))

    Em vez de usar IF()podemos usar IFS()também nas fórmulas acima.

    A solução é baseada na minha outra resposta para Como converter uma coluna de contagens de idade em um conjunto útil para estatísticas?

    Uma versão mais curta, já que esses números também podemos usar os seguintes e não IF()ou IFS()necessários:

    =LET(α, A2:C2, δ, SEQUENCE(MAX(α)), TOROW(A1:C1+δ/(δ<=α),2,1))

    E

    =LET(α, A2:C2, Σ, A1:C1, TOROW((A3:C3/XLOOKUP(Σ,Σ,α))/(SEQUENCE(MAX(α))<=α),2,1))
    • 3

relate perguntas