Início / coding / Perguntas / 78057686
Accepted
Q Qere
Asked: 2024-02-26 05:00:24 +0800 CST

Digitação de função em TypedRacket

  • 772

É possível escrever algo semelhante ao C++

template <typename... T> std::string dup(int n, std::string s, T... tail) {
  std::string result;
  for (int i = 0; i < n; ++i) {
      result += s;
  }
  if constexpr (sizeof...(tail) == 0) {
    return result;
  } else {
    return result + dup(tail...);
  }
}


std::cout << dup(1, std::string("abc"), 2, std::string("xyz"), 3, std::string("a")) << std::endl; // abcxyzxyzaaa

Tentei escrever a seguinte função em TypedRacket

#lang typed/racket

(: repeat-string (-> Integer String String))
(define (repeat-string n str)
  (apply string-append (build-list n (λ (_) str))))

(: dup (All (T ...) (-> Integer String T ... T String)))
(define (dup n s . tail)
  (define result (repeat-string n s))
  (cond [(empty? tail) result]
        [else (string-append result (apply dup tail))])
  )

mas tenho um erro de verificação de digitação: Type Checker: Bad arguments to function in 'apply': Domain: Integer String T ... T Arguments: (List T ... T) in: (apply dup tail)

Honestamente, não entendo por que os argumentos existem, (List T ... T)mas não (T ... T). Além disso, a função está correta, Racket não digitado produz os resultados corretos

racket

1 respostas

  1. Best Answer

    A chave para fazer isso com segurança de tipo adequada é especificar o tipo de sua função usando ->*uma #:rest-starpalavra-chave:

    #lang typed/racket

;; Version that avoids building an intermediate list
(: repeat-string : Integer String -> String)
(define (repeat-string n s)
  (define len (string-length s))
  (build-string (* n len) (lambda (i) (string-ref s (remainder i len)))))


(: dup (->* (Integer String) #:rest-star (Integer String) String))
(define (dup n s . rest)
  (if (null? rest)
      (repeat-string n s)
      (string-append (repeat-string n s) (apply dup rest))))

(dup 1 "abc" 2 "xyz" 3 "a") ; "abcxyzxyzaaa"

    Se sua função recebe uma lista diretamente, você pode usar Rece List*para criar a assinatura de tipo. Você também pode definir dupem termos disso:

    (: dup* : (Rec IntStrRepeated (U Null (List* Integer String IntStrRepeated))) -> String)
(define (dup* pairs)
  (if (null? pairs)
      ""
      (string-append (repeat-string (car pairs) (cadr pairs)) (dup* (cddr pairs)))))

(: dup (->* (Integer String) #:rest-star (Integer String) String))
(define (dup n s . rest)
  (dup* (list* n s rest)))


(dup* '(1 "abc" 2 "xyz" 3 "a")) ; "abcxyzxyzaaa"
    • 1

relate perguntas