Início / coding / Perguntas / 77945236
Accepted
Maddy
Asked: 2024-02-06 12:23:32 +0800 CST

Como escrever uma fórmula no Excel que soma inversamente até que um valor seja encontrado

  • 772

Preciso escrever uma fórmula na coluna D que some os valores da coluna C. Ela precisa começar na célula adjacente a um valor na coluna B e continuar adicionando as células acima até que haja outro valor na coluna B. Então por exemplo, somaria 11, depois 15 e pararia. Em seguida, some 14 e 26. Então 14,5 iria para a mesma linha do próximo valor em B, etc. Há uma lacuna diferente entre os valores na coluna B a cada vez, então não posso simplesmente dizer para olhar 2 ou 3 células para trás . Pode ser qualquer número.

Tentei usar uma combinação de funções de soma, índice e correspondência, mas não consigo encontrar uma sintaxe correta

Trecho da planilha

excel-formula

2 respostas

  1. Best Answer

    É mais fácil se você adicionar uma coluna de agrupamento em D, =IF(B1=1,D1+1,D1). Depois de ter grupos, torna-se uma soma simples: =IF(B2=1,SUMIFS($C$2:$C$10,$D$2:$D$10,D2),"").

    insira a descrição da imagem aqui

    • 0

  2. Supondo que não haja, Excel Constraintsde acordo com as tags postadas, também é possível usar a seguinte fórmula usando LAMBDA()funções auxiliares:

    insira a descrição da imagem aqui

    =LET(
     _Fill, DROP(MAP(B1:B10,LAMBDA(x,SUM(B1:x))),-1),
     IF(B2:B10<>"",MAP(_Fill,LAMBDA(x,SUM((x=_Fill)*C2:C10))),""))

    Outra alternativa usando uma LAMBDA()função auxiliar:

    insira a descrição da imagem aqui

    =LET(
     a, C2:C10,
     b, SEQUENCE(ROWS(a)),
     c, TOCOL(b/B2:B10,3),
     d, MAP(DROP(VSTACK(1,c+1),-1),c,LAMBDA(e,f,SUM(INDEX(a,SEQUENCE(f-e+1,,e))))),
     IFNA(INDEX(d,MATCH(b,c,)),""))
    • 0

relate perguntas