Início / coding / Perguntas / 77941187
Accepted
Thorsten Kettner
Asked: 2024-02-05 21:07:54 +0800 CST

Agregação em coleção no Oracle PL/SQL

  • 772

Existe uma maneira legal de agregar dados de tabela em PL/SQL e obter um único valor e uma coleção em uma consulta? Em outras palavras, podemos combinar facilmente as duas consultas a seguir

SELECT AVG(sal)
INTO v_sal
FROM emp;

SELECT DISTINCT deptno
BULK COLLECT INTO v_deptnos
FROM emp;

em algo assim:

SELECT AVG(sal), ARRAY_AGG(DISTINCT deptno)
INTO v_sal, v_deptnos
FROM emp;
oracle

1 respostas

  1. Best Answer

    Usar CASTe COLLECT:

    DECLARE
  v_sal EMP.SAL%TYPE;
  v_deptnos number_list;
BEGIN
  SELECT AVG(sal)
       , CAST(COLLECT(DISTINCT deptno) AS number_list)
  INTO   v_sal
       , v_deptnos
  FROM   emp;

  DBMS_OUTPUT.PUT_LINE(v_sal);
  FOR i IN 1 .. v_deptnos.COUNT LOOP
    DBMS_OUTPUT.PUT_LINE(v_deptnos(i));
  END LOOP;
END;
/

    Que, para os dados de amostra:

    CREATE TABLE emp (deptno, sal) AS
SELECT 1, 100 FROM DUAL UNION ALL
SELECT 1, 200 FROM DUAL UNION ALL
SELECT 1, 300 FROM DUAL UNION ALL
SELECT 2, 100 FROM DUAL UNION ALL
SELECT 2, 200 FROM DUAL UNION ALL
SELECT 3, 300 FROM DUAL;  

CREATE TYPE number_list IS TABLE OF NUMBER;

    Saídas:

    200
1
2
3

    violino

    • 2

relate perguntas