Início / coding / Perguntas / 77558754
Accepted
eespie
Asked: 2023-11-28 01:14:05 +0800 CST

Atraia empresas do Wikidata com sites em inglês

  • 772

Estou tentando consultar empresas que possuem identificadores do Linkedin, ISINS, LEIs ou sites em inglês. Quero apenas uma linha de dados por empresa, se possível.

Estou lutando com a última parte, acho que identifiquei com sucesso que só quero que sites em inglês sejam preenchidos, mas os URLs reais não estão sendo preenchidos no resultado.

SELECT DISTINCT ?item ?itemLabel ?linkedin ?isin ?lei ?website WHERE {
  SERVICE wikibase:label { bd:serviceParam wikibase:language "en". }
  {
    SELECT DISTINCT ?item ?linkedin ?isin ?lei ?website WHERE {
      ?item wdt:P31 wd:Q4830453.
      {
      ?item wdt:P4264 ?linkedin.}
      UNION
      {
      ?item wdt:P946 ?isin.}
      UNION
      {
      ?item wdt:P1278 ?lei.}
      UNION
      {
      ?item wdt:P856 ?statement0.
      ?statement0 p:P856 [ps:P856 ?website ; pq:P407 wd:Q1860] }

    }
    LIMIT 100
  }
}

Resultado da consulta acima

Os outros dados estão sendo preenchidos, mas não os sites. Também estou recebendo vários registros por empresa.

sparql

1 respostas

  1. Best Answer

    No que diz respeito a sites, observe que

    ?item wdt:P856 ?statement0.
?statement0 p:P856 [ps:P856 ?website ; pq:P407 wd:Q1860]

    está errado. Apenas use ?item p:P856 [ps:P856 ?website ; pq:P407 wd:Q1860] .. Verifique Wikidata: tutorial SPARQL § Qualificadores para saber como consultar qualificadores.

    Sua consulta pode ser corrigida selecionando primeiro apenas ?itemter pelo menos uma dessas instruções (usando UNION) e, em seguida, usando OPTIONALpara obter todas e somente as instruções que são realmente especificadas para cada uma ?item.

    A consulta resultante seria algo como:

    SELECT DISTINCT ?item ?itemLabel ?linkedin ?isin ?lei ?website WHERE {
  SERVICE wikibase:label { bd:serviceParam wikibase:language "en". }
  OPTIONAL { ?item wdt:P4264 ?linkedin . }
  OPTIONAL { ?item wdt:P946 ?isin . }
  OPTIONAL { ?item wdt:P1278 ?lei . }
  OPTIONAL { ?item p:P856 [ps:P856 ?website ; pq:P407 wd:Q1860] . }
  {
    SELECT DISTINCT ?item WHERE {
      ?item wdt:P31 wd:Q4830453 .
      { ?item wdt:P4264 ?linkedin . }
      UNION
      { ?item wdt:P946 ?isin . }
      UNION
      { ?item wdt:P1278 ?lei . }
      UNION
      { ?item p:P856 [ps:P856 ?website ; pq:P407 wd:Q1860] . }
      hint:SubQuery hint:runOnce true .
    }
    LIMIT 100
  }
  hint:Prior hint:runFirst true .
}

    Observe que:

    1. Você ainda obterá múltiplas linhas por empresa caso, para a mesma propriedade, mais de um valor tenha sido especificado. Por exemplo, a Apple tem vários sites. Neste caso, para obter apenas uma linha para a Apple você escolhe um site aleatoriamente (ou qualquer critério de sua preferência) ou pode agregá-los usando GROUP_CONCAT.
    2. Usando LIMIT 100na sua subconsulta você pode acabar com resultados incompletos (por exemplo, a mesma empresa pode ter tanto P4264 quanto P946, mas talvez apenas o primeiro ocorra nos 100 primeiros resultados). Para corrigir esse problema, você deve remover o LIMITcomando.
    • 3

relate perguntas