Início / coding / Perguntas / 77497635
Accepted
Rasec Malkic
Asked: 2023-11-17 03:44:57 +0800 CST

Vlookup como fórmula para pesquisar valor com string de texto em um intervalo

  • 772

Estou tentando pesquisar o valor em E1 dentro dos valores em B2:B6 e obter a letra correspondente da coluna A usando o Excel 365.

Tentei com esta fórmula mas parece que não estou usando corretamente TEXTSPLIT()pois a MATCH()função está apresentando erro ou resultado errado.

E1: =MATCH(E1,TEXTSPLIT(B2:B6,",")*1,0)
H1 H2
A 1,6,8,9,11,27
B 2,10,14,21,22,23,24,26,33
C 3
D 4,7
E 12,13

Abaixo o resultado esperado em E3:H3 para valores diferentes para buscar em E1:H1. Obrigado por qualquer ajuda.

insira a descrição da imagem aqui

excel

1 respostas

  1. Best Answer

    Não é necessário usar, TEXTSPLIT()você também pode usar a seguinte fórmula:

    insira a descrição da imagem aqui

    • Fórmula usada na célulaE2

    =LOOKUP(2,1/SEARCH(","&E$1&",",","&$B$2:$B$6&","),$A$2:$A$6)

    Ou comBYCOL()

    insira a descrição da imagem aqui

    =BYCOL(E1:H1,LAMBDA(α, LOOKUP(2,1/SEARCH(","&α&",",","&$B$2:$B$6&","),$A$2:$A$6)))

    Ou comTEXTSPLIT()

    insira a descrição da imagem aqui

    =TOCOL(IFS(IFERROR(--TEXTSPLIT(TEXTAFTER(","&$B$2:$B$6,",",SEQUENCE(,MAX(LEN($B$2:$B$6)-LEN(SUBSTITUTE($B$2:$B$6,",",))+1))),","),"")=E$1,$A$2:$A$6),2)

    Nota: Por que TEXTSPLIT()não está funcionando como você está tentando, é porque a função foi projetada para operar com strings de texto individuais, dividindo-as em linhas e colunas. Quando você passa um array como entrada, a referida função não o reconhece como um array e o assume como uma única coluna de valores e produz o mesmo enquanto o resto é descartado.

    Ou, usandoTOROW()

    insira a descrição da imagem aqui

    =TOROW(IF(1-ISERR(SEARCH(","&E$1&",",","&$B$2:$B$6&",")),$A$2:$A$6,p),2)

    Ou,

    insira a descrição da imagem aqui

    • Fórmula usada na célulaE2

    =BYCOL(IF(1-ISERR(SEARCH(","&E1:H1&",",","&$B$2:$B$6&",")),A2:A6,""),CONCAT)

    Ou, por que não desta forma:

    insira a descrição da imagem aqui

    • Fórmula usada na célulaE2

    =INDEX($A$2:$A$6,XMATCH("*,"&E1&",*",","&$B$2:$B$6&",",2))

    Ou use BYCOL()para derramar

    =BYCOL(E1:H1,LAMBDA(α, INDEX($A$2:$A$6,XMATCH("*,"&α&",*",","&$B$2:$B$6&",",2))))
    • 1

relate perguntas