Início / coding / Perguntas / 77488023
Accepted
Stephan
Asked: 2023-11-15 21:18:13 +0800 CST

Excel SUM partes de uma string

  • 772

no Excel, tenho algumas células contendo números separados por um travessão, como:

Exemplo

Eu uso uma fórmula como

=TRIM(TEKSTBEFORE(G30:G40;"/";1))
arrays

2 respostas

  1. Best Answer

    Tente usarTEXTSPLIT()

    insira a descrição da imagem aqui

    • Fórmula usada na célulaB1

    =SUM(--TEXTSPLIT(A1," / "))

    Ou,

    insira a descrição da imagem aqui

    =MAP(A1:A7,LAMBDA(φ, SUM(--TEXTSPLIT(φ," / "))))

    Editar: conforme o OP comentou:

    Desculpe, acho que não fui claro o suficiente. Tenho que somar todos os primeiros valores, todos os segundos valores e todos os terceiros valores separadamente. Neste exemplo, o resultado seria 4/98/0. Esse seria o resultado final. Obrigado pela resposta aliás

    insira a descrição da imagem aqui

    • Fórmula usada na célulaB1

    =TEXTJOIN(" / ",,BYCOL(TEXTSPLIT(TEXTAFTER(" / "&A1:A7," / ",{1,2,3})," / "),LAMBDA(α, SUM(--α))))

    Também na ** Excel BetaVersão você pode usarGROUPBY()

    insira a descrição da imagem aqui

    =GROUPBY(,--TEXTSPLIT(TEXTAFTER(" / "&A1:A9," / ",{1,2,3})," / "),SUM)

    Ou usandoPIVOTBY()

    insira a descrição da imagem aqui

    =PIVOTBY(,,--TEXTSPLIT(TEXTAFTER(" / "&A1:A9," / ",{1,2,3})," / "),SUM)

    Para saber mais sobre a função Novo Lançado em Beta Versionsof Windows Excel & Macpode ser encontrado aqui:

    • GROUPBY()-> Documentações MSFT
    • PIVOTBY()-> Documentações MSFT
    • 2

  2. Na versão BETA do Excel: =BYCOL(--TEXTSPLIT(TEXTAFTER("/"&A1:A10,"/",SEQUENCE(,3)),"/"),SUM)

    insira a descrição da imagem aqui

    Outro: =MAP(SEQUENCE(,3),LAMBDA(a,SUM(--TEXTSPLIT(TEXTAFTER("/"&A1:A10,"/",a),"/"))))

    Ou se você usa Excel 2021 sem acesso ao LAMBDA: =MMULT(SEQUENCE(,ROWS(A1:A10),,0),--TEXTSPLIT(TEXTAFTER("/"&A1:A10,"/",SEQUENCE(,3)),"/"))

    • 2

relate perguntas