Início / coding / Perguntas / 77482909
Accepted
Sam
Asked: 2023-11-15 02:08:24 +0800 CST

Substitua os últimos 4 dígitos adicionando 1 dígito (excluindo 0x)

  • 772

Eu tenho o seguinte arquivo (test.txt) que desejo alterar a lógica da seguinte forma:

0 becomes 1
1 becomes 2 
2 becomes 3 
3 becomes 4
4 becomes 5
5 becomes 6 
6 becomes 7 
7 becomes 8 
8 becomes 9
9 becomes 0

$ cat test.txt
69|1074330570|1,sip:+121345633210x3Bverstat=TN-Validation-Passed|tel:+12134565534|0
69|1077822111|2,;tel:+12223120011~sip:[email protected];|sip:[email protected]|0

Quero alterar os últimos 4 dígitos, mas quando x está próximo a 0x, 0 não conta. Por exemplo: na primeira linha '+121345633210x', os 4 últimos são 3321. Na segunda linha, '+12223120011', os 4 últimos são 0011 e '+12223120051', os 4 últimos são 0051 A saída deve ser a seguinte:

69|1074330570|1,sip:+121345644320x3Bverstat=TN-Validation-Passed|tel:+12134566645|0
69|1077822111|2,;tel:+12223121122~sip:[email protected];|sip:[email protected]|0

É necessário excluir '+1' e depois contar '10' dígitos nos quais desejo substituir os 4 últimos na terceira e quarta colunas.

121345633210 becomes 121345644320 / 12134565534 becomes 12134566645
12223120011  becomes 12223121122  / 12223120051 becomes 12223121162 / 13123120022 becomes 13123121133

Usei a lógica abaixo quando a coluna é apenas um número. Mas neste caso, tem outras coisas, então a lógica abaixo não está funcionando, mas é correto converter números adicionando 1 dígito.

awk -F"|" -v OFS="|" '
NR>0 {                                                      
    for (i=3;i<=4;i++) {                                   
        str = substr($i, 1, length($i) - 4)                 
        for (j = length($i) - 3; j <= length($i); j++) {    
            str = str (substr($i, j, 1) + 1) % 10           
        }
        $i = str                                            
    }
} 
1'
linux

3 respostas

  1. Usando gnu-awk, você pode fazer isso:

    awk '
function repl(s,  i, r, ch) {
   for (i=1; i<=length(s); ++i) {
      ch = substr(s,i,1)
      r = r (ch == 9 ? 0 : ch+1)
   }
   return r
}
BEGIN {FS=OFS="+"}
{
   for (j=2; j<=NF; ++j) {
      if (match($j, /^([0-9]+)([0-9]{4})(0x|[^x0-9]|$)(.*)/, a))
         $j = a[1] repl(a[2]) a[3] a[4]
   }
} 1' file

69|1074330570|1,sip:+121345644320x3Bverstat=TN-Validation-Passed|tel:+12134566645|0
67|1077822111|2,;tel:+12223121122~sip:[email protected];|sip:[email protected]|0
    • 3
  2. Best Answer

    Premissas:

    • a +aparece apenas nos 3º/4º campos e somente na frente de um número de telefone

    Uma awkabordagem:

    awk '
BEGIN { FS=OFS="+" }                               # split input on "+"
      { for (i=2; i<=NF; i++) {                    # loop through fields that start with a phone number
            oldfld = $i                            # save current field
            $i = ""                                # initialize new field
            d1 = substr(oldfld,1,1)                # get 1st digit
            len = (d1 == 1 ? 7 : 6)                # determine length of phone prefix
            $i = substr(oldfld,1,len)              # save everything up to the phone prefix

            for (j=(len+1); j<=(len+4); j++) {     # loop through last 4 digits of phone number
                x = substr(oldfld,j,1)             # get current digit
                $i = $i (x==9 ? 0 : x+1)           # increment and add to new field
            }

            $i = $i substr(oldfld,len+4+1)         # save rest of old field
         }
      }
1                                                  # print current line
' test.txt

    Isso gera:

    69|1074330570|1,sip:+121345644320x3Bverstat=TN-Validation-Passed|tel:+12134566645|0
69|1077822111|2,;tel:+12223121122~sip:[email protected];|sip:[email protected]|0
    • 3

  3. Usando GNU awk para o terceiro argumento para corresponder():

    $ awk '{
    head = ""
    while ( match($0,/([^+]+\+[0-9]{7})([0-9]{4})/,a) ) {
        digs = ""
        for ( i=1; i<=4; i++ ) {
            digs = digs ((substr(a[2],i,1) + 1) % 10)
        }
        head = head a[1] digs
        $0 = substr($0,RSTART+RLENGTH)
    }
    print head $0
}' test.txt
69|1074330570|1,sip:+121345644320x3Bverstat=TN-Validation-Passed|tel:+12134566645|0
69|1077822111|2,;tel:+12223121122~sip:[email protected];|sip:[email protected]|0

    Isso produz a saída esperada sem testar apenas o terceiro ou quarto campo e sem testar 0xporque não há strings em campos diferentes de 3 ou 4 que correspondam ao regexp de destino e, embora você tenha dito ignorar 0seguido por x, na realidade você está simplesmente sempre alterando os primeiros 11 dígitos e qualquer um 0que seja seguido xserá o 12º dígito.

    Você poderia fazer o mesmo usando qualquer awk POSIX com:

    awk '{
    head = ""
    while ( match($0,/\+[0-9]{11}/) ) {
        digs = ""
        for ( i=1; i<=4; i++ ) {
            digs = digs ((substr($0,RSTART+RLENGTH-5+i,1) + 1) % 10)
        }
        head = head substr($0,1,RSTART+RLENGTH-5) digs
        $0 = substr($0,RSTART+RLENGTH)
    }
    print head $0
}' test.txt
    • 3

relate perguntas