Início / coding / Perguntas / 77180361
Accepted
PCM
Asked: 2023-09-26 21:15:15 +0800 CST

Execute a próxima instrução SQL

  • 772

No meu banco de dados, tabelas:

  • test1 - não existe
  • test2--existir
  • test3--existir

Ao executar o bloco abaixo, ocorre um erro "tabela não existe" para test1. No entanto, quero executar a instrução drop abaixo para test2 e test3, apesar do erro, porque, no meu caso, "não existe" é bom para mim, pois vou criar todas as 3 tabelas na próxima etapa.

set serveroutput ON;
BEGIN
    begin
    EXECUTE IMMEDIATE 'drop table test1';
    dbms_output.put_line('test1 dropeed successfully');
    EXECUTE IMMEDIATE 'drop table test2';
    dbms_output.put_line('test2 dropped successfully');
    EXECUTE IMMEDIATE 'drop table test3';
    dbms_output.put_line('test3 dropped successfully');
    exception
        when others then
            dbms_output.put_line('Error >> '|| SQLERRM ||' -->'|| dbms_utility.format_error_backtrace);
    end;
end;

esperando: - ele deve descartar test2 e test3 também, mesmo se obtivermos o erro table doesnot exist para test1.

plsql

2 respostas

  1. Você precisaria capturar explicitamente o erro "tabela não existe" e ignorá-lo, o que pode ser feito da seguinte forma:

    DECLARE
  PROCEDURE drop_table(table_name IN VARCHAR2) IS
  BEGIN
    EXECUTE IMMEDIATE 'DROP TABLE ' || table_name;
    dbms_output.put_line(table_name || ' dropped successfully');
  EXCEPTION
    WHEN OTHERS THEN
    IF SQLCODE != -942
    THEN
      RAISE;
    END IF;
  END drop_table;
BEGIN
  drop_table('test1');
  drop_table('test2');
  drop_table('test3');
EXCEPTION
  WHEN OTHERS THEN
    dbms_output.put_line('Error >> ' || SQLERRM || ' -->' || dbms_utility.format_error_backtrace);
END;
/

    Observe que criei um subprocedimento que elimina a tabela; isso evita replicar a mesma lógica repetidamente.

    • 2
  2. Best Answer

    Você precisa capturar a exceção para cada instrução drop:

    SET serveroutput ON SIZE 999999
CLEAR screen
DECLARE
  table_or_view_dne EXCEPTION;
  PRAGMA EXCEPTION_INIT (table_or_view_dne, -942);
BEGIN
   BEGIN
     EXECUTE IMMEDIATE 'DROP TABLE test1';
   EXCEPTION WHEN table_or_view_dne THEN
     NULL;
   END;
   BEGIN
     EXECUTE IMMEDIATE 'DROP TABLE test2';
   EXCEPTION WHEN table_or_view_dne THEN
     NULL;
   END;
   BEGIN
     EXECUTE IMMEDIATE 'DROP TABLE test3';
   EXCEPTION WHEN table_or_view_dne THEN
     NULL;
   END;
  END;
/
    • 1

relate perguntas