Início / coding / Perguntas / 77153113
Accepted
mmv456
Asked: 2023-09-22 03:25:42 +0800 CST

kdb/Q: Como selecionar linhas onde pelo menos uma coluna não é nula?

  • 772

Eu tenho uma tabela parecida com esta:

EU IA Nome 1_Dia_Hora 2_Dia_Hora
2B Poderia 762
8D Ar 142
W2 Tim 908 332
9H Abelha
5E Gelo 712

Como seleciono apenas as linhas com pelo menos um não nulo nas colunas 1_Day_Time e 2_Day_Time em kdb/Q?

Minha saída pretendida está abaixo, com a linha de ID 9H removida, pois há nulos nas colunas 1_Day_Time e 2_Day_Time:

EU IA Nome 1_Dia_Hora 2_Dia_Hora
2B Poderia 762
8D Ar 142
W2 Tim 908 332
5E Gelo 712
null

2 respostas

  1. Se você tivesse muitas colunas para verificar (em vez de 2), poderia usar este exemplo com uma lista de colunas. A vantagem é que é fácil adicionar mais colunas para consideração:

    q)tab:([]ID:`2B`8D`W2`9H`5E;Name:`May`Air`Tim`Bee`Ice;One_Day_Time:762 0N 908 0N 712;Two_Day_Time:0N 142 332 0N 0N)
q)cls:`One_Day_Time`Two_Day_Time
q)?[tab;enlist(not;(all;enlist,{(null;x)}'[cls]));0b;()]
ID Name One_Day_Time Two_Day_Time
---------------------------------
2B May  762
8D Air               142
W2 Tim  908          332
5E Ice  712

    Também é útil se os nomes das colunas puderem variar.

    • 2
  2. Best Answer

    eu aconselho que você não use nomes de colunas começando com um número (por exemplo, prefira "One_Day_Time" em vez de "1_Day_Time"), caso contrário você precisará de seleção funcional. Mas aqui estão algumas soluções possíveis:

    q)show t: ([] ID:`2B`8D`W2`9H`5E; Name:`May`Air`Tim`Bee`Ice; One_Day_Time: 762 0N 908 0N 712; Two_Day_Time: 0N 143 332 0N 0N)
ID Name One_Day_Time Two_Day_Time
---------------------------------
2B May  762
8D Air               143
W2 Tim  908          332
9H Bee
5E Ice  712

q)select from t where not null[One_Day_Time] & null[Two_Day_Time]
ID Name One_Day_Time Two_Day_Time
---------------------------------
2B May  762
8D Air               143
W2 Tim  908          332
5E Ice  712

q)select from t where (not null One_Day_Time) | (not null Two_Day_Time)
ID Name One_Day_Time Two_Day_Time
---------------------------------
2B May  762
8D Air               143
W2 Tim  908          332
5E Ice  712

q)select from t where {not all null x} each (One_Day_Time,'Two_Day_Time)
ID Name One_Day_Time Two_Day_Time
---------------------------------
2B May  762
8D Air               143
W2 Tim  908          332
5E Ice  712
    • 1

relate perguntas