Início / coding / Perguntas / 77030806
Accepted
Kamichanw
Asked: 2023-09-03 11:23:32 +0800 CST

Como alterar o cursorShape ao arrastar um item para fora do MouseArea?

  • 772

Quero mudar, continuar mudando cursorShapeao arrastar um item para fora do arquivo MouseArea.

Como você pode ver no código a seguir, quando mantenho o mouse em current MouseArea, ele cursorShapeserá alterado para DragCopyCursor. Porém, além disso, se eu mover o mouse para outra área mouseArea, o mouse se tornará ArrowCursornovamente.

import QtQuick
import QtQuick.Controls

Window {
    width: 300
    height: 300
    visible: true
    color: "#1F1F1F"
    Column {
        anchors.centerIn: parent
        Repeater {
            model: 2
            delegate: Rectangle {
                z: mouseArea.drag.active ? 2 : 0
                color: "#aaaaaa"
                width: 300
                height: 50

                MouseArea {
                    id: mouseArea
                    anchors.fill: parent
                    drag.target: rec
                    Binding {
                        when: mouseArea.drag.active
                        mouseArea.cursorShape: Qt.DragCopyCursor
                    }

                    Rectangle {
                        id: rec
                        color: "white"
                        height: parent.height / 2
                        width: parent.width / 2
                        anchors.verticalCenter: parent.verticalCenter
                        anchors.horizontalCenter: parent.horizontalCenter
                        Text {
                            anchors.centerIn: parent
                            text: "test " + index
                            color: "black"
                        }
                        states: [
                            State {
                                when: mouseArea.drag.active
                                AnchorChanges {
                                    target: rec
                                    anchors.verticalCenter: undefined
                                    anchors.horizontalCenter: undefined
                                }
                            }
                        ]
                    }
                }
            }
        }
    }
}
qt

1 respostas

  1. Best Answer

    Se você usar DragHandlerem vez de MouseAreavocê pode mantê-lo cursorShapedurante toda a duração do arrasto. NB para DragHandlerfuncionar, tive que substituir a ancoragem por cálculos explícitos para xe y:

        Column {
        anchors.centerIn: parent
        Repeater {
            model: 2
            delegate: Rectangle {
                id: frame
                z: dragHandler.active ? 2 : 0
                color: "#aaaaaa"
                border.color: "pink"
                width: 300
                height: 50
                Rectangle {
                    id: rec
                    color: "white"
                    height: parent.height / 2
                    width: parent.width / 2
                    x: (frame.width - width) / 2
                    y: (frame.height - height) / 2
                    Text {
                        anchors.centerIn: parent
                        text: "test " + index
                        color: "black"
                    }
                    DragHandler {
                        id: dragHandler
                        target: rec
                        cursorShape: Qt.DragCopyCursor
                        onActiveChanged: {
                            if (!active) {
                                rec.x = (frame.width - rec.width) / 2;
                                rec.y = (frame.height - rec.height) / 2;
                            }
                        }
                    }
                }
            }
        }
    }
    • 0

relate perguntas